[arch-commits] Commit in sysprof/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Frederik Schwan
freswa at gemini.archlinux.org
Wed Feb 9 19:08:18 UTC 2022
Date: Wednesday, February 9, 2022 @ 19:08:18
Author: freswa
Revision: 436774
archrelease: copy trunk to staging-x86_64
Added:
sysprof/repos/staging-x86_64/
sysprof/repos/staging-x86_64/PKGBUILD
(from rev 436773, sysprof/trunk/PKGBUILD)
----------+
PKGBUILD | 77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 77 insertions(+)
Copied: sysprof/repos/staging-x86_64/PKGBUILD (from rev 436773, sysprof/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-02-09 19:08:18 UTC (rev 436774)
@@ -0,0 +1,77 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at aur.archlinux.org>
+# Contributor: Eric Belanger <belanger at astro.umontreal.ca>
+# Contributor: aeolist <aeolist at hotmail.com>
+# Contributor: Gabriel Rauter <rauter.gabriel at gmail.com>
+
+pkgbase=sysprof
+pkgname=(sysprof libsysprof-capture)
+pkgver=3.42.1
+pkgrel=3
+pkgdesc="Kernel based performance profiler"
+url="https://wiki.gnome.org/Apps/Sysprof"
+license=(GPL)
+arch=(x86_64)
+depends=(gtk3 polkit libdazzle)
+makedepends=(yelp-tools git meson)
+_commit=2903f08d02c86e520b07c0df5dcafc18bb8ef059 # tags/3.42.1^0
+source=("git+https://gitlab.gnome.org/GNOME/sysprof.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd sysprof
+ git describe --tags | sed 's/^sysprof-//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd sysprof
+}
+
+build() {
+ # Ensure static library is non-LTO compatible
+ CFLAGS+=" -ffat-lto-objects"
+
+ arch-meson sysprof build
+ meson compile -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+_pick() {
+ local p="$1" f d; shift
+ for f; do
+ d="$srcdir/$p/${f#$pkgdir/}"
+ mkdir -p "$(dirname "$d")"
+ mv "$f" "$d"
+ rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+ done
+}
+
+package_sysprof() {
+ depends+=(libsysprof-capture)
+ groups=(gnome-extra)
+
+ meson install -C build --destdir "$pkgdir"
+
+ cd "$pkgdir"
+
+ _pick capture usr/lib/libsysprof-capture-*
+ _pick capture usr/lib/pkgconfig/sysprof-capture-*
+ _pick capture usr/include/sysprof-*/sysprof-{address,capture,clock,collector,macros}.h
+ _pick capture usr/include/sysprof-*/sysprof-{platform,version,version-macros}.h
+ _pick capture usr/include/sysprof-*/sysprof-capture-{condition,cursor,reader,types,writer}.h
+}
+
+package_libsysprof-capture() {
+ pkgdesc+=" - capture library"
+ depends=()
+ license=(BSD)
+
+ mv capture/* "$pkgdir"
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 \
+ sysprof/src/libsysprof-capture/COPYING
+}
More information about the arch-commits
mailing list