[arch-commits] Commit in x265/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Evangelos Foutras foutrelis at gemini.archlinux.org
Thu Feb 10 01:29:56 UTC 2022


    Date: Thursday, February 10, 2022 @ 01:29:56
  Author: foutrelis
Revision: 436846

archrelease: copy trunk to staging-x86_64

Added:
  x265/repos/staging-x86_64/
  x265/repos/staging-x86_64/PKGBUILD
    (from rev 436845, x265/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: x265/repos/staging-x86_64/PKGBUILD (from rev 436845, x265/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-02-10 01:29:56 UTC (rev 436846)
@@ -0,0 +1,68 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: kfgz <kfgz at interia.pl>
+
+pkgname=x265
+pkgver=3.5
+pkgrel=2
+pkgdesc='Open Source H265/HEVC video encoder'
+arch=(x86_64)
+url=https://bitbucket.org/multicoreware/x265_git
+license=(GPL)
+depends=(gcc-libs)
+makedepends=(
+  cmake
+  git
+  nasm
+  ninja
+)
+provides=(libx265.so)
+_tag=f0c1022b6be121a753ff02853fbe33da71988656
+source=(git+https://bitbucket.org/multicoreware/x265_git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd x265_git
+
+  git describe --tags
+}
+
+build() {
+  cmake -S x265_git/source -B build-12 -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DHIGH_BIT_DEPTH=TRUE \
+    -DMAIN12=TRUE \
+    -DEXPORT_C_API=FALSE \
+    -DENABLE_CLI=FALSE \
+    -DENABLE_SHARED=FALSE \
+    -Wno-dev
+  ninja -C build-12
+
+  cmake -S x265_git/source -B build-10 -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DHIGH_BIT_DEPTH=TRUE \
+    -DEXPORT_C_API=FALSE \
+    -DENABLE_CLI=FALSE \
+    -DENABLE_SHARED=FALSE \
+    -Wno-dev
+  ninja -C build-10
+
+  cmake -S x265_git/source -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DENABLE_SHARED=TRUE \
+    -DENABLE_HDR10_PLUS=TRUE \
+    -DEXTRA_LIB='x265_main10.a;x265_main12.a' \
+    -DEXTRA_LINK_FLAGS='-L .' \
+    -DLINKED_10BIT=TRUE \
+    -DLINKED_12BIT=TRUE \
+    -Wno-dev
+  ln -s ../build-10/libx265.a build/libx265_main10.a
+  ln -s ../build-12/libx265.a build/libx265_main12.a
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list