[arch-commits] Commit in kicad/repos (4 files)
George Rawlinson
grawlinson at gemini.archlinux.org
Sat Feb 12 01:01:13 UTC 2022
Date: Saturday, February 12, 2022 @ 01:01:13
Author: grawlinson
Revision: 1132371
archrelease: copy trunk to community-testing-x86_64
Added:
kicad/repos/community-testing-x86_64/
kicad/repos/community-testing-x86_64/PKGBUILD
(from rev 1132370, kicad/trunk/PKGBUILD)
kicad/repos/community-testing-x86_64/fix-archive-permissions.patch
(from rev 1132370, kicad/trunk/fix-archive-permissions.patch)
kicad/repos/community-testing-x86_64/fix-version-string.patch
(from rev 1132370, kicad/trunk/fix-version-string.patch)
-------------------------------+
PKGBUILD | 83 ++++++++++++++++++++++++++++++++++++++++
fix-archive-permissions.patch | 11 +++++
fix-version-string.patch | 15 +++++++
3 files changed, 109 insertions(+)
Copied: kicad/repos/community-testing-x86_64/PKGBUILD (from rev 1132370, kicad/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2022-02-12 01:01:13 UTC (rev 1132371)
@@ -0,0 +1,83 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Maintainer: Filipe Laíns <lains at archlinux.org>
+# Contributor: Marq Schneider <queueRAM at gmail.com>
+# Contributor: Nick Østergaard
+# Contributor: Rachel Mant <aur at dragonmux.network>
+
+pkgname=kicad
+pkgver=6.0.2
+pkgrel=1
+pkgdesc='Electronic schematic and printed circuit board (PCB) design tools'
+arch=('x86_64')
+url='http://kicad.org/'
+license=('GPL')
+depends=(
+ 'boost-libs'
+ 'curl'
+ 'glew'
+ 'glm'
+ 'ngspice'
+ 'opencascade'
+ 'python'
+ 'python-wxpython'
+ 'wxgtk3'
+)
+makedepends=(
+ 'git'
+ 'cmake'
+ 'mesa'
+ 'boost'
+ 'swig'
+)
+optdepends=(
+ 'kicad-library: for footprints, symbols and templates'
+ 'kicad-library-3d: for 3D models of components'
+)
+_commit='702e8b891515a401f380e5f60b9840793352442a'
+source=(
+ "$pkgname::git+https://gitlab.com/kicad/code/kicad.git#commit=$_commit"
+ 'fix-archive-permissions.patch'
+ 'fix-version-string.patch'
+)
+sha512sums=('SKIP'
+ 'e655d37f743e131e60ea8143b78c195ea5233b1336a0cd73c3388bf27848240622843e31c895467fcb8af5d74e351676b353c524c835b9dde49e1e6bc85e0dce'
+ '229559222b96f7ff4334e69142934b1ac74cfdb01b76dd16f1d56fcf70dfe06fa928de4bb9ffb46e023f4a3918bceb04fa39758e2673f51354304ebd2ef6d8b0')
+b2sums=('SKIP'
+ 'fd1312d6adc0a9d00734a95a76fd0ed82824cfae0e626bfa2e0a24a710dd7a9f30d8d9d8b80a278d94aab8dd6d06bfe5edb41f03bb3bb8d4c3b5e9f066d49a84'
+ 'bad6ad3b0278e24717cf8b1c5a30989cb9a329aa7e0fd36c9b2197c2031783c4873b1e0fb5ad9827c15cf93271fb910afddac2c853153e9f7f98bd703725732b')
+
+pkgver() {
+ cd "$pkgname"
+ git describe --tags | sed "s/^v//"
+}
+
+prepare() {
+ cd "$pkgname"
+ patch -p1 -i ../fix-archive-permissions.patch
+ patch -p1 -i ../fix-version-string.patch
+}
+
+build() {
+ cmake \
+ -S "$pkgname" \
+ -B build \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DKICAD_USE_OCC=ON \
+ -DKICAD_SCRIPTING_WXPYTHON=ON \
+ -DwxWidgets_CONFIG_EXECUTABLE=/usr/bin/wx-config-gtk3 \
+ -DKICAD_BUILD_I18N=ON \
+ -DKICAD_I18N_UNIX_STRICT_PATH=ON \
+ -DKICAD_BUILD_QA_TESTS=OFF \
+ -Wno-dev
+
+ cmake --build build
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --install build
+}
+
+# vim:set ts=2 sw=2 et:
Copied: kicad/repos/community-testing-x86_64/fix-archive-permissions.patch (from rev 1132370, kicad/trunk/fix-archive-permissions.patch)
===================================================================
--- community-testing-x86_64/fix-archive-permissions.patch (rev 0)
+++ community-testing-x86_64/fix-archive-permissions.patch 2022-02-12 01:01:13 UTC (rev 1132371)
@@ -0,0 +1,11 @@
+--- a/bitmaps_png/CMakeLists.txt
++++ b/bitmaps_png/CMakeLists.txt
+@@ -782,7 +782,7 @@ else()
+ endif()
+
+ add_custom_target( bitmap_archive ALL
+- COMMAND ${TAR} cfz "${TAR_OUTPUT_FILE}" .
++ COMMAND ${TAR} --create --file "${TAR_OUTPUT_FILE}" --gzip --numeric-owner --owner=0 --group=0 .
+ DEPENDS ${ALL_PNGS}
+ BYPRODUCTS ${BITMAP_ARCHIVE_PATH}
+ WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/png
Copied: kicad/repos/community-testing-x86_64/fix-version-string.patch (from rev 1132370, kicad/trunk/fix-version-string.patch)
===================================================================
--- community-testing-x86_64/fix-version-string.patch (rev 0)
+++ community-testing-x86_64/fix-version-string.patch 2022-02-12 01:01:13 UTC (rev 1132371)
@@ -0,0 +1,15 @@
+--- a/CMakeModules/CreateGitVersionHeader.cmake
++++ b/CMakeModules/CreateGitVersionHeader.cmake
+@@ -32,10 +32,10 @@ macro( create_git_version_header _git_src_path )
+ set( _Git_SAVED_LC_ALL "$ENV{LC_ALL}" )
+ set( ENV{LC_ALL} C )
+
+- # Use `git describe --dirty` to create the KiCad version string.
++ # Use `git describe` to create the KiCad version string.
+ execute_process(
+ COMMAND
+- ${GIT_EXECUTABLE} describe --dirty
++ ${GIT_EXECUTABLE} describe
+ WORKING_DIRECTORY ${_git_src_path}
+ OUTPUT_VARIABLE _git_DESCRIBE
+ ERROR_VARIABLE _git_log_error
More information about the arch-commits
mailing list