[arch-commits] Commit in (4 files)

[David Runge]

    Date: Sunday, February 13, 2022 @ 17:04:36
  Author: dvzrv
Revision: 1133068

Add python-humanfriendly as dependency for python-bincopy (dependency for python-spsdk).

Added:
  python-humanfriendly/
  python-humanfriendly/repos/
  python-humanfriendly/trunk/
  python-humanfriendly/trunk/PKGBUILD

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Added: python-humanfriendly/trunk/PKGBUILD
===================================================================
--- python-humanfriendly/trunk/PKGBUILD	                        (rev 0)
+++ python-humanfriendly/trunk/PKGBUILD	2022-02-13 17:04:36 UTC (rev 1133068)
@@ -0,0 +1,34 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=humanfriendly
+pkgname=python-humanfriendly
+pkgver=10.0
+pkgrel=3
+pkgdesc="Human friendly input/output for text interfaces using Python"
+arch=(any)
+url="https://github.com/xolox/python-humanfriendly"
+license=(MIT)
+depends=(python)
+makedepends=(python-setuptools)
+checkdepends=(python-docutils python-mock python-pytest)
+source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
+sha512sums=('496700bcea1dabf003c938558bf807fabb41b71192f69622979dd9e243dda9b4b06c5ac8f65cef217df85ebadf99099dc22b50d63216791a569be11081d267d6')
+b2sums=('6db7f2f11bafcdc087c078eae6123046610594b17899678e445baa18c25b2210cc1d84363d858ab7c57fce6d6b7a189be69dea08c1891d3f5b11ff9900c9bef9')
+
+build() {
+  cd $_name-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd $_name-$pkgver
+  # disable tests that require dusty capturer project
+  pytest -v $_name/tests.py -k "not test_terminal_capabilities and not test_generate_warning and not test_prompt_for_confirmation"
+}
+
+package() {
+  cd $_name-$pkgver
+  python setup.py install --optimize=1 --root="$pkgdir"
+  install -vDm 644 {CHANGELOG,README}.rst -t "$pkgdir/usr/share/doc/$pkgname"
+  install -vDm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname"
+}