[arch-commits] Commit in opencascade/repos (9 files)
Antonio Rojas
arojas at gemini.archlinux.org
Mon Feb 14 16:41:03 UTC 2022
Date: Monday, February 14, 2022 @ 16:41:03
Author: arojas
Revision: 1133188
archrelease: copy trunk to community-staging-x86_64
Added:
opencascade/repos/community-staging-x86_64/
opencascade/repos/community-staging-x86_64/PKGBUILD
(from rev 1133187, opencascade/trunk/PKGBUILD)
opencascade/repos/community-staging-x86_64/cmake-fix-variable.patch
(from rev 1133187, opencascade/trunk/cmake-fix-variable.patch)
opencascade/repos/community-staging-x86_64/ffmpeg4.4.patch
(from rev 1133187, opencascade/trunk/ffmpeg4.4.patch)
opencascade/repos/community-staging-x86_64/fix-install-dir-references.patch
(from rev 1133187, opencascade/trunk/fix-install-dir-references.patch)
opencascade/repos/community-staging-x86_64/opencascade-tbb-2021.patch
(from rev 1133187, opencascade/trunk/opencascade-tbb-2021.patch)
opencascade/repos/community-staging-x86_64/opencascade.sh
(from rev 1133187, opencascade/trunk/opencascade.sh)
opencascade/repos/community-staging-x86_64/skip-license-installation.patch
(from rev 1133187, opencascade/trunk/skip-license-installation.patch)
opencascade/repos/community-staging-x86_64/vtk9.patch
(from rev 1133187, opencascade/trunk/vtk9.patch)
----------------------------------+
PKGBUILD | 123 +++++++++++++++++++++++++++++++++++++
cmake-fix-variable.patch | 11 +++
ffmpeg4.4.patch | 28 ++++++++
fix-install-dir-references.patch | 22 ++++++
opencascade-tbb-2021.patch | 32 +++++++++
opencascade.sh | 24 +++++++
skip-license-installation.patch | 18 +++++
vtk9.patch | 31 +++++++++
8 files changed, 289 insertions(+)
Copied: opencascade/repos/community-staging-x86_64/PKGBUILD (from rev 1133187, opencascade/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,123 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Gabriel Souza Franco <Z2FicmllbGZyYW5jb3NvdXphQGdtYWlsLmNvbQ==>
+# Contributor: Florian Pritz <bluewind at xinu.at>
+# Contributor: Giuseppe Borzi <gborzi at ieee.org>
+# Contributor: Brice Méalier <mealier_brice at yahoo.fr>
+# Contributor: Michele Mocciola <mickele>
+
+pkgname=opencascade
+pkgver=7.5.3
+pkgrel=2
+epoch=1
+pkgdesc="SDK intended for development of applications dealing with 3D CAD data"
+arch=('x86_64')
+url="https://www.opencascade.org"
+license=('LGPL2.1' 'custom:LGPL-exception')
+depends=(
+ 'ffmpeg4.4'
+ 'freeimage'
+ 'gl2ps'
+ 'intel-tbb'
+ 'tk'
+ 'vtk'
+)
+makedepends=(
+ 'git'
+ 'adios2'
+ 'boost'
+ 'cmake'
+ 'eigen'
+ 'gdal'
+ 'glew'
+ 'libharu'
+ 'liblas'
+ 'openvr'
+ 'pdal'
+ 'proj'
+ 'pugixml'
+ 'python'
+ 'python-mpi4py'
+ 'qt5-base'
+ 'rapidjson'
+ 'unixodbc'
+ 'utf8cpp'
+)
+_commit='fecb042498514186bd37fa621cdcf09eb61899a3' # V7_5_3
+source=(
+ "$pkgname::git+https://git.dev.opencascade.org/repos/occt.git#commit=$_commit"
+ 'opencascade.sh'
+ 'fix-install-dir-references.patch'
+ 'cmake-fix-variable.patch'
+ 'skip-license-installation.patch'
+ 'vtk9.patch'
+ 'opencascade-tbb-2021.patch'
+ 'ffmpeg4.4.patch'
+)
+sha512sums=('SKIP'
+ 'a7516028e55fd303dc1cfb61b75c9cb209d431d854b4d1c58f9c19df8ecee9d79da5c8745676c68a2de0980652de4c4d1c5a927c25db1e5146fb1f1f43c5906b'
+ '826b8572eb298696b0005701bca5ad0406151ec7aa88cd53f9ffaf23a306003a48416b6d120dc5c7e3c14d290e9a15ba93943c4846b6fee8bdb06bd699904f79'
+ 'ad6ce2f52462989bd990b52fd5428f3e5cbd4fb15c38d92c0e0954e6afc3368fca961b92efead8e8957213352fb87a469e1bfaccaf14b484351acc0a0bc10485'
+ 'fd8499793b12e4e59420f63351fef9599c3976d307979beea2681b873a340ae673ba643a7060c74bec1dd4801954c99f8f1f1a8bcc3baa3db9cbfce32153675e'
+ '2725df308f23f11faa664391174a4f21bec13328c7b33ba065bfd28988a4bd815c86849d8815fcdb8f6ed5dd1d7b1a38ded1675c1c08dec1276367fc571917c0'
+ '1d6e0321d0b54caf0130b2c6f81dbbdc621913ffa1c38e464d9be65088085fc831ac69788393911a1dd269f4296c93d26c1706d262537912459eb795bc4f742b'
+ '4834d1fae697a580c258e7ce06db1dc05c891c6bf6e81a5125a3483616fb39200806fc17d0b5b79126ef7cdb5818f3e7fb867aabd15061e19b9ffa1fd7ec5aa7')
+b2sums=('SKIP'
+ 'da9db038ed2348d2d7736505eda2f40fe52c836bcedb74d9f369cc53f7d40a330bd87d6aedd773863745cd46e4dbe5876acda2d2d60177f00d5db9cae4f1f102'
+ 'a56cedf43366d52a81301d653834942fb74a4feafb4ac57923448d42164f060f1874a2180688e482c0dac70a5ea1d2fb53d4410503f22626ff5d2bab405a352f'
+ 'bb98b2b53a9a97ae15a353a9dbcc6d92a97ddaa56af0610cefe9de3a4b84c4a6021d9396f7e270c1d379278df069dbf90f9771db64947e52d38ad36bc3c6f913'
+ 'da815c14ad3a8283c4f3cf41b6b19b40408798f64374b909c776f5ab22ee9ccfc2653c09b33c7b550a138007ff2b36b40d742c9fddc7c1ea499dfe58e59f57ea'
+ 'af240c6f9ba62f336f59caa7cff2bb40915137a02f5b03ee54fa17a5ef27d0411800aa981090a17b3d7c780835625bd4b263975eb100aa71fdc58eb1806916ea'
+ '905d13cf39225c1148e215ad37ab601dfe649f3d4d66b099ae028cdf8fb2a92534e7b14361238566c295ae443a3a3dfeb5f69ab51987b952604eb53821fa92cd'
+ 'bf4753cfd5a28acbef35894959f77d9c8ff37d79075042ef70e57cab6ab2816960d61712f759487c1f200ea8b65deb0660b28012867014ebc5dc6cf2dde0a6dc')
+
+pkgver() {
+ cd "$pkgname"
+ git describe --tags | sed -e "s/^V//" -e "s/_/./g" -e "s/p/./"
+}
+
+prepare() {
+ cd "$pkgname"
+
+ patch -p1 -i ../fix-install-dir-references.patch
+ patch -p1 -i ../cmake-fix-variable.patch
+ patch -p1 -i ../vtk9.patch # Fix build with VTK 9 https://gitlab.kitware.com/vtk/vtk/-/issues/18240
+ git cherry-pick -n 5e7632824302761b84cfceb5bfb2241d906d0eb4 # Fix build of FreeCAD
+ patch -p1 -i ../skip-license-installation.patch
+ patch -p1 -i ../opencascade-tbb-2021.patch # Fix build with TBB 2021
+ patch -p1 -i ../ffmpeg4.4.patch # Use FFmpeg 4.4
+}
+
+build() {
+ cmake \
+ -B build \
+ -S "$pkgname" \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DBUILD_RELEASE_DISABLE_EXCEPTIONS=OFF \
+ -DUSE_FREEIMAGE=ON \
+ -DUSE_FFMPEG=ON \
+ -DUSE_VTK=ON \
+ -DUSE_RAPIDJSON=ON \
+ -DUSE_TBB=ON \
+ -D3RDPARTY_VTK_INCLUDE_DIR=/usr/include/vtk
+ cmake --build build
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --install build
+
+ # environment variables (adapted from adm/templates/env.sh)
+ install -vDm644 -t "$pkgdir/etc/profile.d" opencascade.sh
+
+ # remove unnecessary shell scripts
+ rm -v "$pkgdir/usr/bin/"*.sh
+
+ cd "$pkgname"
+
+ # licenses
+ install -vDm755 -t "$pkgdir/usr/share/licenses/$pkgname" \
+ LICENSE_LGPL_21.txt OCCT_LGPL_EXCEPTION.txt
+}
+
+# vim:set ts=2 sw=2 et:
Copied: opencascade/repos/community-staging-x86_64/cmake-fix-variable.patch (from rev 1133187, opencascade/trunk/cmake-fix-variable.patch)
===================================================================
--- community-staging-x86_64/cmake-fix-variable.patch (rev 0)
+++ community-staging-x86_64/cmake-fix-variable.patch 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,11 @@
+--- a/adm/templates/OpenCASCADEConfig.cmake.in
++++ b/adm/templates/OpenCASCADEConfig.cmake.in
+@@ -27,7 +27,7 @@ get_filename_component (OpenCASCADE_INSTALL_PREFIX "${OpenCASCADE_INSTALL_PREFIX
+ if (OpenCASCADE_INSTALL_PREFIX MATCHES "/cmake$")
+ get_filename_component (OpenCASCADE_INSTALL_PREFIX "${OpenCASCADE_INSTALL_PREFIX}" PATH)
+ endif()
+-if (OpenCASCADE_INSTALL_PREFIX MATCHES "/lib$")
++if (OpenCASCADE_INSTALL_PREFIX MATCHES "/lib(64)?$")
+ get_filename_component (OpenCASCADE_INSTALL_PREFIX "${OpenCASCADE_INSTALL_PREFIX}" PATH)
+ endif()
+ if (OpenCASCADE_INSTALL_PREFIX MATCHES "/libs/${CMAKE_ANDROID_ARCH_ABI}$")
Copied: opencascade/repos/community-staging-x86_64/ffmpeg4.4.patch (from rev 1133187, opencascade/trunk/ffmpeg4.4.patch)
===================================================================
--- community-staging-x86_64/ffmpeg4.4.patch (rev 0)
+++ community-staging-x86_64/ffmpeg4.4.patch 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,28 @@
+diff --git a/adm/cmake/ffmpeg.cmake b/adm/cmake/ffmpeg.cmake
+index f619d2d41..554c9669e 100644
+--- a/adm/cmake/ffmpeg.cmake
++++ b/adm/cmake/ffmpeg.cmake
+@@ -93,12 +93,12 @@ if (NOT 3RDPARTY_FFMPEG_INCLUDE_DIR OR NOT EXISTS "${3RDPARTY_FFMPEG_INCLUDE_DIR
+ if (3RDPARTY_FFMPEG_DIR AND EXISTS "${3RDPARTY_FFMPEG_DIR}")
+ find_path (3RDPARTY_FFMPEG_INCLUDE_DIR NAMES ${HEADER_NAMES}
+ PATHS ${3RDPARTY_FFMPEG_DIR}
+- PATH_SUFFIXES include
++ PATH_SUFFIXES include include/ffmpeg4.4
+ CMAKE_FIND_ROOT_PATH_BOTH
+ NO_DEFAULT_PATH)
+ else()
+ find_path (3RDPARTY_FFMPEG_INCLUDE_DIR NAMES ${HEADER_NAMES}
+- PATH_SUFFIXES include
++ PATH_SUFFIXES include include/ffmpeg4.4
+ CMAKE_FIND_ROOT_PATH_BOTH)
+ endif()
+ endif()
+@@ -116,7 +116,7 @@ foreach (LIBRARY_NAME ${CSF_FFmpeg})
+ if (NOT 3RDPARTY_FFMPEG_LIBRARY_${LIBRARY_NAME} OR NOT EXISTS "${3RDPARTY_FFMPEG_LIBRARY_${LIBRARY_NAME}}")
+ set (CMAKE_FIND_LIBRARY_SUFFIXES .lib .so .dylib .a)
+
+- set (FFMPEG_PATH_SUFFIXES lib)
++ set (FFMPEG_PATH_SUFFIXES lib lib/ffmpeg4.4)
+ if (ANDROID)
+ set (FFMPEG_PATH_SUFFIXES ${FFMPEG_PATH_SUFFIXES} libs/${ANDROID_ABI})
+ elseif(APPLE)
Copied: opencascade/repos/community-staging-x86_64/fix-install-dir-references.patch (from rev 1133187, opencascade/trunk/fix-install-dir-references.patch)
===================================================================
--- community-staging-x86_64/fix-install-dir-references.patch (rev 0)
+++ community-staging-x86_64/fix-install-dir-references.patch 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,22 @@
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -1229,7 +1229,7 @@ foreach (OCCT_CONFIGURATION ${CMAKE_CONFIGURATION_TYPES})
+ endforeach()
+ # install OpenCASCADE config file with compile definitions and C/C++ flags ONLY for current configuration
+ install (CODE "string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWER)")
+-install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
++install (CODE "configure_file(\"${CMAKE_BINARY_DIR}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" \"\$ENV{DESTDIR}${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADECompileDefinitionsAndFlags-\${CMAKE_INSTALL_CONFIG_NAME_LOWER}.cmake\" COPYONLY)")
+
+ foreach (OCCT_MODULE ${OCCT_MODULES})
+ if (BUILD_MODULE_${OCCT_MODULE})
+--- a/adm/cmake/occt_macros.cmake
++++ b/adm/cmake/occt_macros.cmake
+@@ -592,7 +592,7 @@ macro (OCCT_UPDATE_TARGET_FILE)
+ "cmake_policy(PUSH)
+ cmake_policy(SET CMP0007 NEW)
+ string (TOLOWER \"\${CMAKE_INSTALL_CONFIG_NAME}\" CMAKE_INSTALL_CONFIG_NAME_LOWERCASE)
+- file (GLOB ALL_OCCT_TARGET_FILES \"${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADE*Targets-\${CMAKE_INSTALL_CONFIG_NAME_LOWERCASE}.cmake\")
++ file (GLOB ALL_OCCT_TARGET_FILES \"\$ENV{DESTDIR}${INSTALL_DIR}/${INSTALL_DIR_CMAKE}/OpenCASCADE*Targets-\${CMAKE_INSTALL_CONFIG_NAME_LOWERCASE}.cmake\")
+ foreach(TARGET_FILENAME \${ALL_OCCT_TARGET_FILES})
+ file (STRINGS \"\${TARGET_FILENAME}\" TARGET_FILE_CONTENT)
+ file (REMOVE \"\${TARGET_FILENAME}\")
Copied: opencascade/repos/community-staging-x86_64/opencascade-tbb-2021.patch (from rev 1133187, opencascade/trunk/opencascade-tbb-2021.patch)
===================================================================
--- community-staging-x86_64/opencascade-tbb-2021.patch (rev 0)
+++ community-staging-x86_64/opencascade-tbb-2021.patch 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,32 @@
+--- a/src/OSD/OSD_Parallel_TBB.cxx
++++ b/src/OSD/OSD_Parallel_TBB.cxx
+@@ -25,7 +25,7 @@ Standard_DISABLE_DEPRECATION_WARNINGS
+ #include <tbb/parallel_for.h>
+ #include <tbb/parallel_for_each.h>
+ #include <tbb/blocked_range.h>
+-#include <tbb/task_scheduler_init.h>
++#include <tbb/global_control.h>
+ Standard_ENABLE_DEPRECATION_WARNINGS
+
+ //=======================================================================
+@@ -38,19 +38,12 @@ void OSD_Parallel::forEachExternal (UniversalIterator& theBegin,
+ const FunctorInterface& theFunctor,
+ Standard_Integer theNbItems)
+ {
+- try
+- {
+ const Handle(OSD_ThreadPool)& aThreadPool = OSD_ThreadPool::DefaultPool();
+ const Standard_Integer aNbThreads = theNbItems > 0 ?
+ aThreadPool->NbDefaultThreadsToLaunch() : -1;
+
+- tbb::task_scheduler_init aScheduler (aNbThreads);
++ tbb::global_control global_limit(tbb::global_control::max_allowed_parallelism, aNbThreads);
+ tbb::parallel_for_each (theBegin, theEnd, theFunctor);
+- }
+- catch (tbb::captured_exception& anException)
+- {
+- throw Standard_ProgramError (anException.what());
+- }
+ }
+
+ #endif /* HAVE_TBB */
Copied: opencascade/repos/community-staging-x86_64/opencascade.sh (from rev 1133187, opencascade/trunk/opencascade.sh)
===================================================================
--- community-staging-x86_64/opencascade.sh (rev 0)
+++ community-staging-x86_64/opencascade.sh 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,24 @@
+export CASROOT=/usr
+
+export CSF_LANGUAGE=us
+export MMGT_CLEAR=1
+export CSF_EXCEPTION_PROMPT=1
+
+export CSF_OCCTResourcePath=$CASROOT/share/opencascade/resources
+export CSF_SHMessage=$CSF_OCCTResourcePath/SHMessage
+export CSF_MDTVTexturesDirectory=$CSF_OCCTResourcePath/Textures
+export CSF_ShadersDirectory=$CSF_OCCTResourcePath/Shaders
+export CSF_XSMessage=$CSF_OCCTResourcePath/XSMessage
+export CSF_TObjMessage=$CSF_OCCTResourcePath/TObj
+export CSF_StandardDefaults=$CSF_OCCTResourcePath/StdResource
+export CSF_PluginDefaults=$CSF_OCCTResourcePath/StdResource
+export CSF_XCAFDefaults=$CSF_OCCTResourcePath/StdResource
+export CSF_TObjDefaults=$CSF_OCCTResourcePath/StdResource
+export CSF_StandardLiteDefaults=$CSF_OCCTResourcePath/StdResource
+export CSF_IGESDefaults=$CSF_OCCTResourcePath/XSTEPResource
+export CSF_STEPDefaults=$CSF_OCCTResourcePath/XSTEPResource
+export CSF_XmlOcafResource=$CSF_OCCTResourcePath/XmlOcafResource
+export CSF_MIGRATION_TYPES=$CSF_OCCTResourcePath/StdResource/MigrationSheet.txt
+export CSF_DrawPluginDefaults=$CSF_OCCTResourcePath/DrawResources
+export DRAWHOME=$CSF_OCCTResourcePath/DrawResources
+export DRAWDEFAULT=$CSF_OCCTResourcePath/DrawResources/DrawDefault
Copied: opencascade/repos/community-staging-x86_64/skip-license-installation.patch (from rev 1133187, opencascade/trunk/skip-license-installation.patch)
===================================================================
--- community-staging-x86_64/skip-license-installation.patch (rev 0)
+++ community-staging-x86_64/skip-license-installation.patch 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,18 @@
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -337,15 +337,6 @@ endif()
+ # include occt macros
+ OCCT_INCLUDE_CMAKE_FILE ("adm/cmake/occt_resources")
+
+-# install LICENSE_LGPL_21.txt and OCCT_LGPL_EXCEPTION.txt files
+-if ("${INSTALL_DIR_LAYOUT}" STREQUAL "Unix")
+- OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" "${INSTALL_DIR_DOC}")
+- OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" "${INSTALL_DIR_DOC}")
+-else()
+- OCCT_INSTALL_FILE_OR_DIR ("LICENSE_LGPL_21.txt" ".")
+- OCCT_INSTALL_FILE_OR_DIR ("OCCT_LGPL_EXCEPTION.txt" ".")
+-endif()
+-
+ if(APPLE)
+ set (INSTALL_NAME_DIR "" CACHE STRING "install_name library suffix on OS X (e.g. @executable_path/../Frameworks)")
+ endif()
Copied: opencascade/repos/community-staging-x86_64/vtk9.patch (from rev 1133187, opencascade/trunk/vtk9.patch)
===================================================================
--- community-staging-x86_64/vtk9.patch (rev 0)
+++ community-staging-x86_64/vtk9.patch 2022-02-14 16:41:03 UTC (rev 1133188)
@@ -0,0 +1,31 @@
+--- a/src/IVtkDraw/IVtkDraw_HighlightAndSelectionPipeline.hxx
++++ b/src/IVtkDraw/IVtkDraw_HighlightAndSelectionPipeline.hxx
+@@ -23,6 +23,7 @@
+
+ // prevent disabling some MSVC warning messages by VTK headers
+ #include <Standard_WarningsDisable.hxx>
++#undef AllValues
+ #include <vtkActor.h>
+ #include <vtkPolyData.h>
+ #include <vtkPolyDataMapper.h>
+--- a/src/IVtkVTK/IVtkVTK_ShapeData.hxx
++++ b/src/IVtkVTK/IVtkVTK_ShapeData.hxx
+@@ -23,6 +23,7 @@
+ #include <vtkPolyData.h>
+ #include <vtkSmartPointer.h>
+ #include <vtkIdTypeArray.h>
++#include <vtkVersion.h>
+ #include <Standard_WarningsRestore.hxx>
+
+ class vtkIdTypeArray;
+--- a/src/InterfaceGraphic/InterfaceGraphic.hxx
++++ b/src/InterfaceGraphic/InterfaceGraphic.hxx
+@@ -40,6 +40,8 @@
+ #include <X11/Xatom.h>
+ #include <GL/glx.h>
+
++#undef AllValues
++
+ #endif
+
+ #endif // __INTERFACE_GRAPHIC_HXX
More information about the arch-commits
mailing list