[arch-commits] Commit in libiio/repos (2 files)
David Runge
dvzrv at gemini.archlinux.org
Thu Feb 17 11:10:54 UTC 2022
Date: Thursday, February 17, 2022 @ 11:10:54
Author: dvzrv
Revision: 1133696
archrelease: copy trunk to community-staging-x86_64
Added:
libiio/repos/community-staging-x86_64/
libiio/repos/community-staging-x86_64/PKGBUILD
(from rev 1133695, libiio/trunk/PKGBUILD)
----------+
PKGBUILD | 65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 65 insertions(+)
Copied: libiio/repos/community-staging-x86_64/PKGBUILD (from rev 1133695, libiio/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-02-17 11:10:54 UTC (rev 1133696)
@@ -0,0 +1,65 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+# needs rebuild on minor soname bumps
+
+pkgbase=libiio
+pkgname=(libiio python-pylibiio)
+pkgver=0.23
+pkgrel=4
+pkgdesc="Interface to the Linux Industrial Input/Output (IIO) Subsystem"
+arch=(x86_64)
+url="https://github.com/analogdevicesinc/libiio"
+license=(LGPL2.1)
+makedepends=(avahi cmake libaio libserialport libusb libxml2 python-setuptools)
+options=(debug)
+source=("$pkgname-$pkgver.tar.gz::https://github.com/analogdevicesinc/$pkgname/archive/v$pkgver.tar.gz")
+sha512sums=('d3b1e1da46764025d757d558ba623730ac08c590261e546aa3c8e628959a74e40c90eedfc1eb2198f4a67a14e1900647fd150d7545e2c7cb44e72bbbab5f116a')
+b2sums=('9dfbeee48a0685496f9f257c947b791b91c1e675f33437aa8f7ce9afd0763df641fd90dbaf3a0d41c1b63dc7ad54c437a12992ede7f10582ebf2a2bc0aa92695')
+
+_pick() {
+ local p="$1" f d; shift
+ for f; do
+ d="$srcdir/$p/${f#$pkgdir/}"
+ mkdir -p "$(dirname "$d")"
+ mv "$f" "$d"
+ rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+ done
+}
+
+build() {
+ cmake -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_SBINDIR=bin \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DCMAKE_BUILD_TYPE=None \
+ -DPYTHON_BINDINGS=ON \
+ -DSYSTEMD_UNIT_INSTALL_DIR=/usr/lib/systemd/system \
+ -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
+ -DWITH_MAN=ON \
+ -DWITH_SYSTEMD=ON \
+ -DWITH_SERIAL_BACKEND=ON \
+ -Wno-dev \
+ -B build \
+ -S $pkgname-$pkgver
+ make -C build VERBOSE=1
+}
+
+package_libiio() {
+ depends+=(gcc-libs glibc libaio libserialport libxml2 libavahi-client.so libavahi-common.so libusb-1.0.so)
+ optdepends=('python-pylibiio: for Python bindings')
+ provides=(libiio.so)
+
+ make DESTDIR="$pkgdir" -C build install
+ install -vDm 644 $pkgname-$pkgver/{CONTRIBUTING,Contributors,README}.md -t "$pkgdir/usr/share/doc/$pkgname"
+
+ (
+ cd "$pkgdir"
+ _pick pylibiio usr/lib/python*
+ )
+}
+
+package_python-pylibiio() {
+ pkgdesc+=" - Python bindings"
+ depends=(libiio=$pkgver python)
+
+ mv -v pylibiio/* "$pkgdir"
+}
More information about the arch-commits
mailing list