[arch-commits] Commit in obsidian/repos (5 files)
Sven-Hendrik Haase
svenstaro at gemini.archlinux.org
Thu Feb 17 15:45:47 UTC 2022
Date: Thursday, February 17, 2022 @ 15:45:46
Author: svenstaro
Revision: 1133711
archrelease: copy trunk to community-x86_64
Added:
obsidian/repos/community-x86_64/
obsidian/repos/community-x86_64/PKGBUILD
(from rev 1133710, obsidian/trunk/PKGBUILD)
obsidian/repos/community-x86_64/Packaging permission from Arch Linux.eml
(from rev 1133710, obsidian/trunk/Packaging permission from Arch Linux.eml)
obsidian/repos/community-x86_64/obsidian
(from rev 1133710, obsidian/trunk/obsidian)
obsidian/repos/community-x86_64/obsidian.desktop
(from rev 1133710, obsidian/trunk/obsidian.desktop)
------------------+
PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
obsidian | 2 ++
obsidian.desktop | 11 +++++++++++
3 files changed, 61 insertions(+)
Copied: obsidian/repos/community-x86_64/PKGBUILD (from rev 1133710, obsidian/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD (rev 0)
+++ community-x86_64/PKGBUILD 2022-02-17 15:45:46 UTC (rev 1133711)
@@ -0,0 +1,48 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Contributor: Gennadiy Mykhailiuta <gmykhailiuta at gmail.com>
+# Contributor: Xuanwo <xuanwo at archlinuxcn.org>
+
+pkgname=obsidian
+pkgver=0.13.23
+pkgrel=2
+pkgdesc="A powerful knowledge base that works on top of a local folder of plain text Markdown files"
+arch=('x86_64')
+url="https://obsidian.md/"
+license=('custom:Commercial')
+depends=('zlib' 'hicolor-icon-theme' 'fuse' 'electron13')
+makedepends=('asar')
+options=(!strip)
+source=(
+ "${pkgname}"
+ "${pkgname}.desktop"
+ "https://github.com/obsidianmd/obsidian-releases/releases/download/v${pkgver}/obsidian-${pkgver}.tar.gz"
+)
+sha256sums=('5f4699e03045f68932e976727a746342f971eddb77fe5a31d8d2c4084034ed5f'
+ '1153b7f4ce342663f766efa38dc07677aec13f7f619afef1f9b8e2b1f1849fe6'
+ '0c393639b516e40b5866ed0eb010373b9abd7ba143193389615b2e9fb7711db2')
+
+prepare() {
+ cd "$srcdir"
+ asar ef "${pkgname}-${pkgver}"/resources/obsidian.asar icon.png
+}
+
+package() {
+ cd "$srcdir"
+
+ # Create directories for installation
+ install -dm0755 "$pkgdir"/usr/bin
+ install -dm0755 "$pkgdir"/usr/lib/obsidian
+
+ # Install executable file
+ install -Dm755 "$pkgname" "$pkgdir"/usr/bin/
+
+ # Install desktop file
+ install -Dm644 "$pkgname".desktop -t "$pkgdir"/usr/share/applications/
+ install -Dm644 icon.png "$pkgdir"/usr/share/pixmaps/obsidian.png
+
+ # Most of the release package is electron, but we use system's default one
+ # So strip away asar packages and put them to /usr/lib/
+ cd "${pkgname}-${pkgver}"/resources/
+ find . -type d -exec install -d {,"$pkgdir"/usr/lib/obsidian/}{} \;
+ find . -type f -exec install -D {,"$pkgdir"/usr/lib/obsidian/}{} \;
+}
Copied: obsidian/repos/community-x86_64/Packaging permission from Arch Linux.eml (from rev 1133710, obsidian/trunk/Packaging permission from Arch Linux.eml)
===================================================================
(Binary files differ)
Copied: obsidian/repos/community-x86_64/obsidian (from rev 1133710, obsidian/trunk/obsidian)
===================================================================
--- community-x86_64/obsidian (rev 0)
+++ community-x86_64/obsidian 2022-02-17 15:45:46 UTC (rev 1133711)
@@ -0,0 +1,2 @@
+#!/bin/sh
+exec /bin/electron13 /usr/lib/obsidian/app.asar "$@"
Copied: obsidian/repos/community-x86_64/obsidian.desktop (from rev 1133710, obsidian/trunk/obsidian.desktop)
===================================================================
--- community-x86_64/obsidian.desktop (rev 0)
+++ community-x86_64/obsidian.desktop 2022-02-17 15:45:46 UTC (rev 1133711)
@@ -0,0 +1,11 @@
+[Desktop Entry]
+Name=Obsidian
+Exec=/usr/bin/obsidian %U
+Terminal=false
+Type=Application
+Icon=obsidian
+StartupWMClass=obsidian
+X-AppImage-Version=0.12.5
+Comment=Obsidian
+MimeType=x-scheme-handler/obsidian;
+Categories=Office;
More information about the arch-commits
mailing list