[arch-commits] Commit in tpm2-tss/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Jonas Witschel]

    Date: Friday, February 18, 2022 @ 15:53:06
  Author: diabonas
Revision: 1133977

archrelease: copy trunk to community-x86_64

Added:
  tpm2-tss/repos/community-x86_64/PKGBUILD
    (from rev 1133976, tpm2-tss/trunk/PKGBUILD)
Deleted:
  tpm2-tss/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   92 +++++++++++++++++++++++++++++++++----------------------------
 1 file changed, 50 insertions(+), 42 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-02-18 15:52:51 UTC (rev 1133976)
+++ PKGBUILD	2022-02-18 15:53:06 UTC (rev 1133977)
@@ -1,42 +0,0 @@
-# Maintainer: Jonas Witschel <diabonas at archlinux.org>
-# Contributor: Bruno Pagani <archange at archlinux.org>
-pkgname=tpm2-tss
-pkgver=3.1.0
-pkgrel=1
-pkgdesc='Implementation of the TCG Trusted Platform Module 2.0 Software Stack (TSS2)'
-arch=('x86_64')
-url='https://github.com/tpm2-software/tpm2-tss'
-license=('BSD')
-depends=('curl' 'json-c' 'openssl' 'libjson-c.so')
-makedepends=('cmocka' 'doxygen')
-checkdepends=('iproute2' 'swtpm' 'uthash')
-provides=('libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-sys.so' 'libtss2-tctildr.so')
-backup=('etc/tpm2-tss/fapi-config.json'
-        'etc/tpm2-tss/fapi-profiles/P_ECCP256SHA256.json'
-        'etc/tpm2-tss/fapi-profiles/P_RSA2048SHA256.json')
-options=('!emptydirs')
-source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
-sha512sums=('8967f172c92f1e3e5ba324dbe8afe07bf1bc7179dd755cef9812105f32634f312ee7cc7dfe8e13af69dc219432463f5dc9b93477743de47aba6af1d70b252405'
-            'SKIP')
-validpgpkeys=('D6B4D8BAC7E0CC97DCD4AC7272E88B53F7A95D84'  # Andreas Fuchs <andreas.fuchs at sit.fraunhofer.de>
-              '5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts at intel.com>
-
-build() {
-	cd "$pkgname-$pkgver"
-	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
-	            --with-runstatedir=/run --with-sysusersdir=/usr/lib/sysusers.d \
-	            --with-tmpfilesdir=/usr/lib/tmpfiles.d --with-udevrulesprefix=60- \
-	            --enable-unit $( ((CHECKFUNC)) && echo --enable-integration)
-	make
-}
-
-check() {
-	cd "$pkgname-$pkgver"
-	make check
-}
-
-package() {
-	cd "$pkgname-$pkgver"
-	make DESTDIR="$pkgdir" install
-	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
-}

Copied: tpm2-tss/repos/community-x86_64/PKGBUILD (from rev 1133976, tpm2-tss/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-02-18 15:53:06 UTC (rev 1133977)
@@ -0,0 +1,50 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+# Contributor: Bruno Pagani <archange at archlinux.org>
+pkgname=tpm2-tss
+pkgver=3.2.0
+pkgrel=1
+pkgdesc='Implementation of the TCG Trusted Platform Module 2.0 Software Stack (TSS2)'
+arch=('x86_64')
+url='https://github.com/tpm2-software/tpm2-tss'
+license=('BSD')
+depends=('curl' 'json-c' 'openssl' 'libjson-c.so')
+makedepends=('cmocka' 'doxygen' 'libtpms')
+checkdepends=('iproute2' 'swtpm' 'uthash')
+provides=('libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-sys.so' 'libtss2-tctildr.so')
+backup=('etc/tpm2-tss/fapi-config.json'
+        'etc/tpm2-tss/fapi-profiles/P_ECCP256SHA256.json'
+        'etc/tpm2-tss/fapi-profiles/P_RSA2048SHA256.json')
+options=('debug' '!emptydirs' '!lto')
+source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc}
+        'https://raw.githubusercontent.com/tpm2-software/tpm2-tss/e237e4d33cbf280292a480edd8ad061dcd3a37a2/lib/tss2-tcti-libtpms.map')
+sha512sums=('cabb411f074dfa94919ba914849aac77a0ac2f50622e28a1406cf575369148774748e0e2b7a7c566ec83561a96d4b883bac5a3b1763f4cf48668a0c5d68c0a23'
+            'SKIP'
+            '55be966eb320c96ca49b3aaa0635815076fe1a21149d1a0f95654778c8359bd16f18a10c0cabe955a366d4a14e2645a8150878b601085d987727de40831e50ab')
+validpgpkeys=('D6B4D8BAC7E0CC97DCD4AC7272E88B53F7A95D84'  # Andreas Fuchs <andreas.fuchs at sit.fraunhofer.de>
+              '5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts at intel.com>
+
+prepare() {
+	cd "$pkgname-$pkgver"
+	# Add file missing from release tarball (https://github.com/tpm2-software/tpm2-tss/issues/2313)
+	cp "$srcdir/tss2-tcti-libtpms.map" lib
+}
+
+build() {
+	cd "$pkgname-$pkgver"
+	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+	            --with-runstatedir=/run --with-sysusersdir=/usr/lib/sysusers.d \
+	            --with-tmpfilesdir=/usr/lib/tmpfiles.d --with-udevrulesprefix=60- \
+	            --enable-unit $( ((CHECKFUNC)) && echo --enable-integration)
+	make
+}
+
+check() {
+	cd "$pkgname-$pkgver"
+	make check
+}
+
+package() {
+	cd "$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}