[arch-commits] Commit in bat/repos (2 files)
David Runge
dvzrv at gemini.archlinux.org
Fri Feb 18 17:30:00 UTC 2022
Date: Friday, February 18, 2022 @ 17:29:59
Author: dvzrv
Revision: 1134007
archrelease: copy trunk to community-staging-x86_64
Added:
bat/repos/community-staging-x86_64/
bat/repos/community-staging-x86_64/PKGBUILD
(from rev 1134006, bat/trunk/PKGBUILD)
----------+
PKGBUILD | 58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 58 insertions(+)
Copied: bat/repos/community-staging-x86_64/PKGBUILD (from rev 1134006, bat/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-02-18 17:29:59 UTC (rev 1134007)
@@ -0,0 +1,58 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Wesley Moore <wes at wezm.net>
+
+pkgname=bat
+pkgver=0.19.0
+pkgrel=2
+pkgdesc='Cat clone with syntax highlighting and git integration'
+arch=(x86_64)
+url='https://github.com/sharkdp/bat'
+license=(APACHE MIT)
+depends=(gcc-libs libgit2 oniguruma)
+makedepends=(clang cmake git rust)
+source=("git+$url#commit=59a8f58be780ba9ba04eb4791b6bf5ca14e99e99") # tag: v0.19.0
+b2sums=('SKIP')
+
+prepare() {
+ cargo fetch \
+ --locked \
+ --manifest-path "$srcdir/$pkgname/Cargo.toml"
+}
+
+build() {
+ export CFLAGS+=' -ffat-lto-objects -w'
+ cargo build \
+ --locked \
+ --manifest-path "$srcdir/$pkgname/Cargo.toml" \
+ --release
+}
+
+check() {
+ cargo test \
+ --locked \
+ --manifest-path "$srcdir/$pkgname/Cargo.toml"
+}
+
+package() {
+ install -Dm755 $pkgname/target/release/$pkgname "$pkgdir/usr/bin/$pkgname"
+
+ # Package licenses
+ install -Dm644 $pkgname/LICENSE-APACHE \
+ "$pkgdir/usr/share/licenses/$pkgname/LICENSE-APACHE"
+ install -Dm644 $pkgname/LICENSE-MIT \
+ "$pkgdir/usr/share/licenses/$pkgname/LICENSE-MIT"
+
+ cd $pkgname/target/release/build
+
+ # Find and package the man page (because cargo --out-dir is too new)
+ find . -name bat.1 -type f -exec install -Dm644 {} \
+ "$pkgdir/usr/share/man/man1/bat.1" \;
+
+ # Find and package the zsh completion file (not in zsh-completions yet)
+ find . -name bat.zsh -type f -exec install -Dm644 {} \
+ "$pkgdir/usr/share/zsh/site-functions/_bat" \;
+
+ # Find and package the fish completion file
+ find . -name bat.fish -type f -exec install -Dm644 {} \
+ "$pkgdir/usr/share/fish/vendor_completions.d/bat.fish" \;
+}
More information about the arch-commits
mailing list