[arch-commits] Commit in git-cliff/repos (2 files)

[Caleb Maclennan]

    Date: Friday, February 18, 2022 @ 18:06:24
  Author: alerque
Revision: 1134017

archrelease: copy trunk to community-staging-x86_64

Added:
  git-cliff/repos/community-staging-x86_64/
  git-cliff/repos/community-staging-x86_64/PKGBUILD
    (from rev 1134016, git-cliff/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: git-cliff/repos/community-staging-x86_64/PKGBUILD (from rev 1134016, git-cliff/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-18 18:06:24 UTC (rev 1134017)
@@ -0,0 +1,42 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+
+pkgname=git-cliff
+pkgver=0.6.0
+pkgrel=2
+pkgdesc="A highly customizable changelog generator"
+arch=('x86_64')
+url="https://github.com/orhun/git-cliff"
+license=('GPL3')
+depends=('gcc-libs' 'zlib' 'libgit2' 'libgit2.so')
+makedepends=('cargo')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha512sums=('f50ab6ef0f18836de9efe98a349acd8dfa3f57e030347f7a375b59a39d5d02a1dc7f44bb24beba5c215461416c5d81ba11f38e2168514284e37342ccfa77a52d')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  mkdir completions/
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release --frozen
+  OUT_DIR=completions/ cargo run --release --bin git-cliff-completions
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  cargo test --frozen -- --skip "git_log"
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+  install -Dm 644 "completions/$pkgname.bash" "$pkgdir/usr/share/bash-completion/completions/$pkgname"
+  install -Dm 644 "completions/$pkgname.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d"
+  install -Dm 644 "completions/_$pkgname" -t "$pkgdir/usr/share/zsh/site-functions"
+}
+
+# vim: ts=2 sw=2 et: