[arch-commits] Commit in git-delta/repos (2 files)

[Caleb Maclennan]

    Date: Friday, February 18, 2022 @ 18:12:46
  Author: alerque
Revision: 1134028

archrelease: copy trunk to community-staging-x86_64

Added:
  git-delta/repos/community-staging-x86_64/
  git-delta/repos/community-staging-x86_64/PKGBUILD
    (from rev 1134027, git-delta/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: git-delta/repos/community-staging-x86_64/PKGBUILD (from rev 1134027, git-delta/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-18 18:12:46 UTC (rev 1134028)
@@ -0,0 +1,67 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
+# Contributor: ccorn
+
+pkgname=git-delta
+_pkgname=delta
+pkgver=0.12.0
+pkgrel=2
+pkgdesc='Syntax-highlighting pager for git and diff output'
+arch=('x86_64')
+url="https://github.com/dandavison/delta"
+license=('MIT')
+depends=('libgit2')
+makedepends=('rust' 'mdbook')
+checkdepends=('git')
+options=('!lto')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha512sums=('409a49974073f1a92cde2922df57e4a8539901a63c0896486c8b09f0e2b7edeea86b97baa3eb743cd175bdfc70cb67eb7db5eb164796820162ca623cc6bf085b')
+b2sums=('bb9deff579f98fa6a6ff27b69f4d374db4d0ff1e3c848379d6a9ed132b529ed5017f06230de8677f32019e3d4820c22bca9551bc761c8c55b03be1817e585dc2')
+
+prepare() {
+  cd "$_pkgname-$pkgver"
+
+  # download dependencies
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$_pkgname-$pkgver"
+
+  # binary
+  cargo build --frozen --release --all-features
+
+  # html manual
+  cd manual
+  mdbook build --dest-dir html
+}
+
+check() {
+  cd "$_pkgname-$pkgver"
+  # some tests hang for 60+ seconds, find out why
+  # took my machine ~ 470 seconds
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/delta
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+  # shell auto-completions
+  install -vDm644 etc/completion/completion.bash \
+    "$pkgdir/usr/share/bash-completion/completions/$_pkgname"
+  install -vDm644 etc/completion/completion.zsh \
+    "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+  # html manual
+  cp -r manual/html "$pkgdir/usr/share/doc/$pkgname"
+}