[arch-commits] Commit in starship/repos (2 files)

Caleb Maclennan alerque at gemini.archlinux.org
Fri Feb 18 18:21:06 UTC 2022


    Date: Friday, February 18, 2022 @ 18:21:06
  Author: alerque
Revision: 1134050

archrelease: copy trunk to community-staging-x86_64

Added:
  starship/repos/community-staging-x86_64/
  starship/repos/community-staging-x86_64/PKGBUILD
    (from rev 1134048, starship/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: starship/repos/community-staging-x86_64/PKGBUILD (from rev 1134048, starship/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-18 18:21:06 UTC (rev 1134050)
@@ -0,0 +1,63 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Kevin Song <kevin.s05 at gmail.com>
+
+pkgname=starship
+pkgdesc='The cross-shell prompt for astronauts'
+_tag=e6a921b5b2a54ffd81368f9b3a573e49b5af1c9a
+pkgver=1.3.0
+pkgrel=2
+arch=(x86_64)
+url=https://starship.rs/
+license=(ISC)
+depends=(
+  gcc-libs
+  glibc
+  libgit2.so
+  openssl
+  ttf-font-nerd
+)
+makedepends=(
+  git
+  rust
+)
+checkdepends=(python)
+source=(git+https://github.com/starship/starship.git#tag=${_tag})
+b2sums=('SKIP')
+
+prepare() {
+  cargo fetch \
+    --locked \
+    --target $CARCH-unknown-linux-gnu \
+    --manifest-path starship/Cargo.toml
+}
+
+pkgver() {
+  cd starship
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  export CARGO_TARGET_DIR=target
+  cargo build \
+    --release \
+    --frozen \
+    --manifest-path starship/Cargo.toml
+}
+
+check() {
+  cargo test \
+    --frozen \
+    --manifest-path starship/Cargo.toml
+}
+
+package() {
+  install -Dm 755 target/release/starship -t "${pkgdir}"/usr/bin/
+  install -Dm 644 starship/LICENSE -t "${pkgdir}"/usr/share/licenses/starship/
+  install -dm 755 "${pkgdir}"/usr/share/{bash-completion/completions,fish/vendor_completions.d,zsh/site-functions}/
+  ./target/release/starship completions bash > "${pkgdir}"/usr/share/bash-completion/completions/starship
+  ./target/release/starship completions fish > "${pkgdir}"/usr/share/fish/vendor_completions.d/starship.fish
+  ./target/release/starship completions zsh > "${pkgdir}"/usr/share/zsh/site-functions/_starship
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list