[arch-commits] Commit in cargo-tarpaulin/repos (2 files)

[David Runge]

    Date: Friday, February 18, 2022 @ 18:24:50
  Author: dvzrv
Revision: 1134062

archrelease: copy trunk to community-staging-x86_64

Added:
  cargo-tarpaulin/repos/community-staging-x86_64/
  cargo-tarpaulin/repos/community-staging-x86_64/PKGBUILD
    (from rev 1134061, cargo-tarpaulin/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: cargo-tarpaulin/repos/community-staging-x86_64/PKGBUILD (from rev 1134061, cargo-tarpaulin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-18 18:24:50 UTC (rev 1134062)
@@ -0,0 +1,57 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+
+pkgname=cargo-tarpaulin
+pkgver=0.19.1
+pkgrel=2
+pkgdesc='Tool to analyse test coverage of cargo projects'
+arch=(x86_64)
+url=https://github.com/xd009642/tarpaulin
+license=(Apache MIT)
+depends=(
+  gcc-libs
+  glibc
+  libcurl.so
+  openssl
+  libssh2
+  libgit2
+  zlib
+)
+makedepends=(
+  git
+  rust
+)
+_tag=dfbaea14237157235edb3921ac168169a0d0e7d6
+source=(git+https://github.com/xd009642/tarpaulin.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+  cd tarpaulin
+
+  git describe --tags
+}
+
+prepare() {
+  cargo fetch \
+    --locked \
+    --target $CARCH-unknown-linux-gnu \
+    --manifest-path tarpaulin/Cargo.toml
+}
+
+build() {
+  export CARGO_TARGET_DIR=target
+  export LIBSSH2_SYS_USE_PKG_CONFIG=1
+  cargo build \
+    --release \
+    --frozen \
+    --manifest-path tarpaulin/Cargo.toml
+}
+
+package() {
+  cd tarpaulin
+  install -Dm 755 "${srcdir}/target/release/${pkgname}" -t "${pkgdir}"/usr/bin/
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE-MIT -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: