[arch-commits] Commit in gitui/repos (2 files)

[Caleb Maclennan]

    Date: Friday, February 18, 2022 @ 19:21:14
  Author: alerque
Revision: 1134155

archrelease: copy trunk to community-staging-x86_64

Added:
  gitui/repos/community-staging-x86_64/
  gitui/repos/community-staging-x86_64/PKGBUILD
    (from rev 1134154, gitui/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: gitui/repos/community-staging-x86_64/PKGBUILD (from rev 1134154, gitui/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-18 19:21:14 UTC (rev 1134155)
@@ -0,0 +1,43 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Simon Hauser <Simon-Hauser at outlook.de>
+# Contributor: Wesley Moore <wes at wezm.net>
+
+pkgname=gitui
+pkgver=0.20.1
+pkgrel=2
+pkgdesc='Blazing fast terminal-ui for git written in Rust'
+url='https://github.com/extrawurst/gitui'
+arch=('x86_64')
+license=('MIT')
+# work around two libssl.so providers being in the repos by only depending on package for now
+depends=('gcc-libs' 'libgit2' 'libgit2.so' 'libxcb' 'openssl' 'zlib')
+makedepends=('cargo' 'python') # xcb crate needs python
+source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('eccec120dfd4c5c33a74d331a53f3d0c6cb7200e26b0c4c7873278eb951bc379')
+b2sums=('5954a7eac325f6e15a94380618100b52fa5e121fa12da9a99c65b2693aaec2d7ceb2bbef67529775ac8e6e2dc8529df20990c762785262e0416c84b9b0c14868')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  CFLAGS+=" -ffat-lto-objects"
+  cargo build --frozen --release
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  cargo test --frozen
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dm 755 target/release/gitui -t "${pkgdir}/usr/bin/"
+  install -Dm 644 {KEY_CONFIG,README,THEMES}.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: