[arch-commits] Commit in haskell-streaming-commons/repos (2 files)

[Felix Yan]

    Date: Saturday, February 19, 2022 @ 00:32:22
  Author: felixonmars
Revision: 1134727

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-streaming-commons/repos/community-staging-x86_64/
  haskell-streaming-commons/repos/community-staging-x86_64/PKGBUILD
    (from rev 1134726, haskell-streaming-commons/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: haskell-streaming-commons/repos/community-staging-x86_64/PKGBUILD (from rev 1134726, haskell-streaming-commons/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-02-19 00:32:22 UTC (rev 1134727)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=streaming-commons
+pkgname=haskell-streaming-commons
+pkgver=0.2.2.3
+pkgrel=4
+pkgdesc="Common lower-level functions needed by various streaming data libraries"
+url="https://github.com/fpco/streaming-commons"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-network' 'haskell-random' 'haskell-zlib')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a47941a6e0e11e08010ab93bf406ae2c9b1de2bc46328fadee83591d88030649276d07fc60ef78160e177e2167df5c8b8bbf6582721731cd0abfc124b49bf56c')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-use-bytestring-builder
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}