[arch-commits] Commit in sqlfluff/repos (community-any community-any/PKGBUILD)

[George Rawlinson]

    Date: Sunday, February 20, 2022 @ 07:16:01
  Author: grawlinson
Revision: 1135222

archrelease: copy trunk to community-any

Added:
  sqlfluff/repos/community-any/
  sqlfluff/repos/community-any/PKGBUILD
    (from rev 1135221, sqlfluff/trunk/PKGBUILD)

----------+
 PKGBUILD |   79 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

Copied: sqlfluff/repos/community-any/PKGBUILD (from rev 1135221, sqlfluff/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-02-20 07:16:01 UTC (rev 1135222)
@@ -0,0 +1,79 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Morteza NourelahiAlamdari <m at 0t1.me>
+
+pkgname=sqlfluff
+pkgver=0.10.1
+pkgrel=2
+pkgdesc="A dialect-flexible and configurable SQL linter"
+arch=('any')
+url="https://www.sqlfluff.com"
+license=('MIT')
+depends=(
+  'python'
+  'python-appdirs'
+  'python-cached-property'
+  'python-chardet'
+  'python-click'
+  'python-colorama'
+  'python-diff-cover'
+  'python-jinja'
+  'python-oyaml'
+  'python-pathspec'
+  'python-pytest'
+  'python-regex'
+  'python-tblib'
+  'python-toml'
+  'python-tqdm'
+  'python-typing_extensions'
+)
+makedepends=(
+  'git'
+  'python-build'
+  'python-wheel'
+  'python-installer'
+)
+checkdepends=('python-hypothesis')
+_commit='73a66ff5172580e6c4bc61f1facb3d366db4e0d9' # 0.10.1
+source=("$pkgname::git+https://github.com/sqlfluff/sqlfluff.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd "$pkgname"
+
+  python \
+    -m build \
+    --wheel \
+    --no-isolation
+}
+
+check() {
+  cd "$pkgname"
+
+  # skip failing tests for now
+  PYTHONPATH="$PWD/src:$PYTHONPATH" pytest \
+    --ignore test/core/plugin_test.py \
+    --ignore plugins/sqlfluff-templater-dbt \
+    --ignore plugins/sqlfluff-plugin-example \
+    --deselect test/test_testing.py::test_rules__test_helper_has_variable_introspection
+}
+
+package() {
+  cd "$pkgname"
+
+  python \
+    -m installer \
+    --destdir "$pkgdir" \
+    dist/*.whl
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.md
+}