[arch-commits] Commit in aardvark-dns/repos (2 files)

[David Runge]

    Date: Sunday, February 20, 2022 @ 13:08:57
  Author: dvzrv
Revision: 1135273

archrelease: copy trunk to community-x86_64

Added:
  aardvark-dns/repos/community-x86_64/
  aardvark-dns/repos/community-x86_64/PKGBUILD
    (from rev 1135272, aardvark-dns/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: aardvark-dns/repos/community-x86_64/PKGBUILD (from rev 1135272, aardvark-dns/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2022-02-20 13:08:57 UTC (rev 1135273)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+
+pkgname=aardvark-dns
+_commit=5cd145d2ccf420cef739751e1c26e1ddca06d048  # refs/tags/v1.0.0^{}
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="Authoritative dns server for A/AAAA container records"
+arch=(x86_64)
+url="https://github.com/containers/aardvark-dns"
+license=(Apache)
+depends=(gcc-libs glibc)
+makedepends=(cargo git libgit2)
+source=("git+https://github.com/containers/aardvark-dns.git#commit=$_commit")
+sha256sums=('SKIP')
+# NOTE: pinning commit until upstream clarifies commitment to chain of trust:
+# https://github.com/containers/aardvark-dns/issues/83
+# validpgpkeys=('74FE091D25519980B2D84447160386BECB6F0643')  # Brent Baude <bbaude at redhat.com>
+
+prepare() {
+  cd $pkgname
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+
+  cd $pkgname
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  export RUSTUP_TOOLCHAIN=stable
+
+  cd $pkgname
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd $pkgname
+  install -vDm 755 target/release/$pkgname -t "$pkgdir/usr/lib/podman/"
+  install -vDm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}