[arch-commits] Commit in expat/repos (staging-x86_64 staging-x86_64/PKGBUILD)
David Runge
dvzrv at gemini.archlinux.org
Sun Feb 20 19:43:57 UTC 2022
Date: Sunday, February 20, 2022 @ 19:43:57
Author: dvzrv
Revision: 437813
archrelease: copy trunk to staging-x86_64
Added:
expat/repos/staging-x86_64/
expat/repos/staging-x86_64/PKGBUILD
(from rev 437812, expat/trunk/PKGBUILD)
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Copied: expat/repos/staging-x86_64/PKGBUILD (from rev 437812, expat/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-02-20 19:43:57 UTC (rev 437813)
@@ -0,0 +1,41 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Judd Vinet <jvinet at zeroflux.org>
+
+pkgname=expat
+pkgver=2.4.6
+pkgrel=1
+pkgdesc="An XML parser library"
+arch=(x86_64)
+url="https://libexpat.github.io/"
+license=(MIT)
+depends=(glibc)
+makedepends=(cmake)
+provides=(libexpat.so)
+options=(debug)
+source=("https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/${pkgname}-${pkgver}.tar.bz2"{,.asc})
+sha512sums=('87e9e9597867fc73352122b89ea3e1d0dba0d81640b1defd7633bb13108b89e1703b69358021b90f0af29854020ddbc07bf56ea6acc764e5bdecd51ee6050d99'
+ 'SKIP')
+b2sums=('4f41b019107f1dfc5d1b45fd5844069472e5ad2e5208ef5d7b9e4a9bdb020440d46c5ef1c7cc34fb846fc1f63b37b5ac57b692dfdcb59e52c94383945b0f456d'
+ 'SKIP')
+validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping
+
+build() {
+ cmake -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -W no-dev \
+ -B build \
+ -S "$pkgname-$pkgver"
+ make VERBOSE=1 -C build
+}
+
+check() {
+ make VERBOSE=1 -C build test
+}
+
+package() {
+ make VERBOSE=1 DESTDIR="$pkgdir" -C build install
+ install -vDm 644 "$pkgname-$pkgver/COPYING" -t "${pkgdir}/usr/share/licenses/$pkgname/"
+ install -vDm 644 "$pkgname-$pkgver/"{AUTHORS,Changes,README.md} -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}
More information about the arch-commits
mailing list