[arch-commits] Commit in lib32-expat/repos (2 files)

[David Runge]

    Date: Sunday, February 20, 2022 @ 19:45:34
  Author: dvzrv
Revision: 1135324

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-expat/repos/multilib-staging-x86_64/
  lib32-expat/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1135323, lib32-expat/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: lib32-expat/repos/multilib-staging-x86_64/PKGBUILD (from rev 1135323, lib32-expat/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-02-20 19:45:34 UTC (rev 1135324)
@@ -0,0 +1,49 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+_name=expat
+pkgname=lib32-expat
+pkgver=2.4.6
+pkgrel=1
+pkgdesc='An XML Parser library'
+arch=(x86_64)
+url=https://libexpat.github.io/
+license=(MIT)
+depends=(
+  "expat=${pkgver}"
+  lib32-glibc
+)
+makedepends=(cmake)
+options=(debug)
+source=("https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/${_name}-${pkgver}.tar.bz2"{,.asc})
+sha512sums=('87e9e9597867fc73352122b89ea3e1d0dba0d81640b1defd7633bb13108b89e1703b69358021b90f0af29854020ddbc07bf56ea6acc764e5bdecd51ee6050d99'
+            'SKIP')
+b2sums=('4f41b019107f1dfc5d1b45fd5844069472e5ad2e5208ef5d7b9e4a9bdb020440d46c5ef1c7cc34fb846fc1f63b37b5ac57b692dfdcb59e52c94383945b0f456d'
+        'SKIP')
+validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping
+
+build() {
+  export CC='gcc -m32'
+  export CXX='c++ -m32'
+  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib32 \
+        -DCMAKE_BUILD_TYPE=None \
+        -W no-dev \
+        -B build \
+        -S "${_name}-$pkgver"
+  make VERBOSE=1 -C build
+}
+
+check() {
+  make VERBOSE=1 -C build test
+}
+
+package() {
+  make VERBOSE=1 DESTDIR="$pkgdir" -C build install
+  install -vDm 644 "${_name}-$pkgver/COPYING" -t "${pkgdir}/usr/share/licenses/$pkgname/"
+  rm -rf "${pkgdir}"/usr/{bin,include,share/man,share/doc}
+}
+
+# vim: ts=2 sw=2 et: