[arch-commits] Commit in jless/repos (community-x86_64 community-x86_64/PKGBUILD)

[George Rawlinson]

    Date: Friday, February 25, 2022 @ 19:10:37
  Author: grawlinson
Revision: 1136606

archrelease: copy trunk to community-x86_64

Added:
  jless/repos/community-x86_64/
  jless/repos/community-x86_64/PKGBUILD
    (from rev 1136605, jless/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: jless/repos/community-x86_64/PKGBUILD (from rev 1136605, jless/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2022-02-25 19:10:37 UTC (rev 1136606)
@@ -0,0 +1,55 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: João Vitor S. Anjos <jvanjos at protonmail dot com>
+
+pkgname=jless
+pkgver=0.7.2
+pkgrel=2
+pkgdesc='A command-line pager for JSON data'
+arch=('x86_64')
+url="https://github.com/PaulJuliusMartinez/jless"
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('git' 'rust')
+options=('!lto')
+_commit='19e0e8747ad7d1dfae395c027ffcda578adb7e5c'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname"
+
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd "$pkgname"
+
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$pkgname"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/jless
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}
+
+# vim:set ts=2 sw=2 et: