[arch-commits] Commit in libffado/trunk (PKGBUILD)

[David Runge]

    Date: Sunday, February 27, 2022 @ 15:13:13
  Author: dvzrv
Revision: 1137713

upgpkg: libffado 2.4.5-1: Upgrade to 2.4.5.

Remove unneeded quotes and curly braces.
Add debug package.

Modified:
  libffado/trunk/PKGBUILD

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++--------------------------------
 1 file changed, 27 insertions(+), 32 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-02-27 15:11:13 UTC (rev 1137712)
+++ PKGBUILD	2022-02-27 15:13:13 UTC (rev 1137713)
@@ -4,56 +4,51 @@
 # Contributor: Jon Kristian Nilsen <jokr.nilsen at gmail.com>
 
 pkgname=libffado
-pkgver=2.4.4
-pkgrel=4
+pkgver=2.4.5
+pkgrel=1
 pkgdesc="Driver for FireWire audio devices"
-arch=('x86_64')
+arch=(x86_64)
 url="http://www.ffado.org/"
-license=('GPL3')
-depends=('gcc-libs' 'glibc' 'glibmm' 'hicolor-icon-theme' 'libavc1394'
-'libiec61883' 'libxml++' 'python-dbus')
-makedepends=('alsa-lib' 'dbus-c++' 'jack' 'libconfig' 'python-pyqt5' 'scons')
+license=(GPL3)
+depends=(gcc-libs glibc glibmm hicolor-icon-theme libavc1394
+libiec61883 libxml++ python-dbus)
+makedepends=(alsa-lib dbus-c++ jack libconfig python-pyqt5 scons)
 optdepends=('python-pyqt5: ffado-mixer')
-provides=('libffado.so')
-source=("http://www.ffado.org/files/${pkgname}-${pkgver}.tgz")
-sha512sums=('065b7f9ce9bf58320c02353b63ed17b3610d0ee8a2de58de27159b2190e39c779094b01ae1123c087387e6077375e646b564b9e7717b192865b2f1f22a3acc80')
-b2sums=('70d3b17f7d7317acc63351faaefb27fa850664015134887f0508b4a76aabbf6e9573f87eb2dd9792ac5f4f4b06ac7c872afa33af6af0341e6cceeb43e7a79526')
+provides=(libffado.so)
+options=(debug)
+source=(http://www.ffado.org/files/$pkgname-$pkgver.tgz)
+sha512sums=('a2c1d0515e14015b7803c4d52d67605afec27ae2569888dec085375ed4a488f4885b5033369e52305e668a35289d3bd749a9babb5778df339fa93553c23af30f')
+b2sums=('18c260b782c9a97e3f2c8689a218f7a4925158c3e3cb14987182bf04043438d1325a9ababfe29860f6769a5eeabb49a843a8d15072b24b914334c447b5c7238d')
 
 prepare() {
-  cd "${pkgname}-${pkgver}"
+  cd $pkgname-$pkgver
   # fix icon name, so it's coherent with XDG desktop file name
-  sed -e 's/hi64-apps-ffado/ffado-mixer/g' \
-      -i support/xdg/ffado.org-ffadomixer.desktop
+  sed -e 's/hi64-apps-ffado/ffado-mixer/g' -i support/xdg/ffado.org-ffadomixer.desktop
   # fix id, so it's coherent with XDG desktop file name
-  sed -e 's/ffado.org-ffadomixer.desktop/ffado-mixer.desktop/g' \
-      -i support/xdg/ffado-mixer.appdata.xml
+  sed -e 's/ffado.org-ffadomixer.desktop/ffado-mixer.desktop/g' -i support/xdg/ffado-mixer.appdata.xml
 }
 
 build() {
   local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
-  cd "${pkgname}-${pkgver}"
+
+  cd $pkgname-$pkgver
   scons PREFIX=/usr \
         DEBUG=no \
         CUSTOM_ENV=True \
-        MANDIR='/usr/share/man' \
-        PYTHON_INTERPRETER='/usr/bin/python3' \
-        PYPKGDIR="/usr/lib/python${python_version}/site-packages" \
-        UDEVDIR='/usr/lib/udev/rules.d'
+        MANDIR=/usr/share/man \
+        PYTHON_INTERPRETER=/usr/bin/python3 \
+        PYPKGDIR=/usr/lib/python$python_version/site-packages \
+        UDEVDIR=/usr/lib/udev/rules.d
 }
 
 package() {
-  depends+=('libasound.so' 'libconfig++.so' 'libdbus-c++-1.so' )
-  cd "${pkgname}-${pkgver}"
-  scons DESTDIR="${pkgdir}" WILL_DEAL_WITH_XDG_MYSELF="True" install
+  depends+=(libasound.so libconfig++.so libdbus-c++-1.so)
 
-  # XDG
-  install -vDm 644 support/xdg/ffado.org-ffadomixer.desktop \
-    "${pkgdir}/usr/share/applications/ffado-mixer.desktop"
-  install -vDm 644 support/xdg/hi64-apps-ffado.png \
-    "${pkgdir}/usr/share/icons/hicolor/64x64/apps/ffado-mixer.png"
-
-  # docs
-  install -t "${pkgdir}/usr/share/doc/${pkgname}" -vDm 644 {AUTHORS,README}
+  cd $pkgname-$pkgver
+  scons DESTDIR="$pkgdir" WILL_DEAL_WITH_XDG_MYSELF=True install
+  install -vDm 644 support/xdg/ffado.org-ffadomixer.desktop "$pkgdir/usr/share/applications/ffado-mixer.desktop"
+  install -vDm 644 support/xdg/hi64-apps-ffado.png "$pkgdir/usr/share/icons/hicolor/64x64/apps/ffado-mixer.png"
+  install -vDm 644 {AUTHORS,README} -t "$pkgdir/usr/share/doc/$pkgname/"
 }
 
 # vim:set ts=2 sw=2 et: