[arch-commits] Commit in python-astroid/repos/community-any (PKGBUILD PKGBUILD)

Caleb Maclennan alerque at gemini.archlinux.org
Mon Feb 28 08:31:32 UTC 2022


    Date: Monday, February 28, 2022 @ 08:31:32
  Author: alerque
Revision: 1138236

archrelease: copy trunk to community-any

Added:
  python-astroid/repos/community-any/PKGBUILD
    (from rev 1138235, python-astroid/trunk/PKGBUILD)
Deleted:
  python-astroid/repos/community-any/PKGBUILD

----------+
 PKGBUILD |   82 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 42 insertions(+), 40 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-02-28 08:31:25 UTC (rev 1138235)
+++ PKGBUILD	2022-02-28 08:31:32 UTC (rev 1138236)
@@ -1,40 +0,0 @@
-# Maintainer: Caleb Maclennan <caleb at alerque.com>
-# Maintainer: Daniel M. Capella <polyzen at archlinux.org>
-# Contributor: Angel Velasquez <angvp at archlinux.org>
-# Contributor: Felix Yan <felixonmars at archlinux.org>
-
-_pyname=astroid
-pkgname=python-$_pyname
-pkgver=2.10.0
-pkgrel=1
-pkgdesc='A common base representation of python source code'
-arch=(any)
-url="https://github.com/PyCQA/$_pyname"
-license=(LGPL)
-_pydeps=(lazy-object-proxy
-         typing-extensions
-         wrapt)
-depends=(python
-         "${_pydeps[@]/#/python-}")
-makedepends=(python-setuptools)
-checkdepends=(python-pytest)
-replaces=(python-logilab-astng)
-conflicts=(python-logilab-astng)
-_archive="$_pyname-$pkgver"
-source=("$url/archive/v$pkgver/$_archive.tar.gz")
-sha256sums=('4115a49a72af431eef200fd677b781f8097241614f28b71ae5fdce9957001124')
-
-build() {
-	cd "$_archive"
-	python setup.py build
-}
-
-check() {
-	cd "$_archive"
-	pytest
-}
-
-package() {
-	cd "$_archive"
-	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
-}

Copied: python-astroid/repos/community-any/PKGBUILD (from rev 1138235, python-astroid/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-02-28 08:31:32 UTC (rev 1138236)
@@ -0,0 +1,42 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Maintainer: Daniel M. Capella <polyzen at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+_pyname=astroid
+pkgname=python-$_pyname
+pkgver=2.10.0
+pkgrel=2
+pkgdesc='A common base representation of python source code'
+arch=(any)
+url="https://github.com/PyCQA/$_pyname"
+license=(LGPL)
+_pydeps=(lazy-object-proxy
+         typing-extensions
+         wrapt)
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(python-{build,installer}
+             python-setuptools
+             python-wheel)
+checkdepends=(python-pytest)
+replaces=(python-logilab-astng)
+conflicts=(python-logilab-astng)
+_archive="$_pyname-$pkgver"
+source=("$url/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('4115a49a72af431eef200fd677b781f8097241614f28b71ae5fdce9957001124')
+
+build() {
+	cd "$_archive"
+	python -m build -wn
+}
+
+check() {
+	cd "$_archive"
+	pytest
+}
+
+package() {
+	cd "$_archive"
+	python -m installer -d "$pkgdir" dist/*.whl
+}



More information about the arch-commits mailing list