[arch-commits] Commit in smplayer/repos (2 files)

[Caleb Maclennan]

    Date: Monday, February 28, 2022 @ 08:40:04
  Author: alerque
Revision: 1138250

archrelease: copy trunk to community-testing-x86_64

Added:
  smplayer/repos/community-testing-x86_64/
  smplayer/repos/community-testing-x86_64/PKGBUILD
    (from rev 1138249, smplayer/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: smplayer/repos/community-testing-x86_64/PKGBUILD (from rev 1138249, smplayer/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-02-28 08:40:04 UTC (rev 1138250)
@@ -0,0 +1,53 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Alessio 'mOLOk' Bolognino <themolok at gmail.com>
+# Contributor: shamrok <szamrok at gmail.com>
+
+pkgname=smplayer
+pkgver=22.2.0
+pkgrel=1
+pkgdesc='Media player with built-in codecs that can play virtually all video and audio formats'
+url='https://www.smplayer.info/'
+arch=('x86_64')
+license=('GPL')
+depends=('glibc' 'qt5-script' 'qt5-base' 'mpv' 'libx11' 'zlib' 'gcc-libs' 'hicolor-icon-theme')
+makedepends=('qt5-tools')
+optdepends=('smplayer-themes: icon themes collection'
+            'smplayer-skins: skin themes collection'
+            'smtube: browse and play youtube videos'
+            'youtube-dl: youtube videos and streaming'
+            'yt-dlp: youtube videos and streaming'
+            'mplayer: alternative multimedia engine')
+source=(https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
+sha512sums=('62916d9df8493efbe810a5de36c2d45fd2e39173e061060c749c87ac498f43ca08caa073bd04b05e3e9de72c5efdf9bece8e08f4c57a0d283d9f78b7687e2d14')
+b2sums=('b10103907dc334f65bf1d0dfc55baef5fe330e84eabb0534d77b4ebeb6b93f677b5f39b9e8ab60f8a7fdaf405fee8ab683e7c5e284256b04a6628603fc476540')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  # make build reproducible, we compress ourselves
+  sed '/gzip -9/d' -i Makefile
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  export CXXFLAGS="${CXXFLAGS} ${CPPFLAGS}"
+  make \
+    PREFIX=/usr \
+    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
+    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE \
+    CFLAGS_EXTRA="${CFLAGS} ${CPPFLAGS} ${LDFLAGS}" \
+    all
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make \
+    PREFIX=/usr \
+    DOC_PATH=/usr/share/doc/smplayer \
+    DESTDIR="${pkgdir}" \
+    install
+}
+
+# vim: ts=2 sw=2 et: