[arch-commits] Commit in haskell-wai-app-static/repos (2 files)

[Felix Yan]

    Date: Saturday, January 1, 2022 @ 03:47:32
  Author: felixonmars
Revision: 1091527

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-wai-app-static/repos/community-staging-x86_64/
  haskell-wai-app-static/repos/community-staging-x86_64/PKGBUILD
    (from rev 1091526, haskell-wai-app-static/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-wai-app-static/repos/community-staging-x86_64/PKGBUILD (from rev 1091526, haskell-wai-app-static/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-01 03:47:32 UTC (rev 1091527)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=wai-app-static
+pkgname=haskell-wai-app-static
+pkgver=3.1.7.2
+pkgrel=263
+pkgdesc="WAI application for static serving"
+url="https://www.yesodweb.com/book/web-application-interface"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-cryptonite'
+         'haskell-file-embed' 'haskell-http-date' 'haskell-http-types' 'haskell-memory'
+         'haskell-mime-types' 'haskell-old-locale' 'haskell-optparse-applicative'
+         'haskell-unix-compat' 'haskell-unordered-containers' 'haskell-wai' 'haskell-wai-extra'
+         'haskell-warp' 'haskell-zlib')
+makedepends=('ghc' 'uusi' 'haskell-hspec' 'haskell-mockery' 'haskell-network' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('e073d85efc201eab94b9c8be4e40ee71567d07ed2e2907504a946477211bc21aaf2250213cac67525ae58be499b164b09880600c0a6f62b0b1742fb9d730d6d9')
+
+prepare() {
+  uusi $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-print
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}