[arch-commits] Commit in haskell-hls-floskell-plugin/repos (2 files)

[Felix Yan]

    Date: Tuesday, January 4, 2022 @ 14:08:28
  Author: felixonmars
Revision: 1092962

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hls-floskell-plugin/repos/community-staging-x86_64/
  haskell-hls-floskell-plugin/repos/community-staging-x86_64/PKGBUILD
    (from rev 1092961, haskell-hls-floskell-plugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-hls-floskell-plugin/repos/community-staging-x86_64/PKGBUILD (from rev 1092961, haskell-hls-floskell-plugin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-04 14:08:28 UTC (rev 1092962)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-floskell-plugin
+pkgname=haskell-hls-floskell-plugin
+pkgver=1.0.0.1
+pkgrel=48
+pkgdesc="Integration with the Floskell code formatter"
+url="https://hackage.haskell.org/package/hls-floskell-plugin"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-floskell' 'haskell-ghcide' 'haskell-hls-plugin-api' 'haskell-lsp-types')
+makedepends=('ghc' 'uusi' 'haskell-hls-test-utils')
+checkdepends=('git')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('0f420355b67447426e77f149a5cf735f613b2c863b08f625e0a0d91a33bcf565684d702f67743ef9d50eaa235551c30c76743fedd78ead9fbed429e838acf113')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}