[arch-commits] Commit in php-apcu/repos (3 files)

[Pierre Schmitz]

    Date: Tuesday, January 4, 2022 @ 17:29:50
  Author: pierre
Revision: 433414

archrelease: copy trunk to staging-x86_64

Added:
  php-apcu/repos/staging-x86_64/
  php-apcu/repos/staging-x86_64/PKGBUILD
    (from rev 433413, php-apcu/trunk/PKGBUILD)
  php-apcu/repos/staging-x86_64/apcu.ini
    (from rev 433413, php-apcu/trunk/apcu.ini)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 apcu.ini |    1 
 2 files changed, 73 insertions(+)

Copied: php-apcu/repos/staging-x86_64/PKGBUILD (from rev 433413, php-apcu/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-01-04 17:29:50 UTC (rev 433414)
@@ -0,0 +1,72 @@
+# Maintainer: Pierre Schmitz <pierre at archlinux.de>
+
+pkgbase=php-apcu
+pkgname=(php-apcu php7-apcu)
+pkgver=5.1.21
+pkgrel=3
+arch=('x86_64')
+pkgdesc='A userland caching module for PHP'
+url='https://pecl.php.net/package/APCu'
+makedepends=('php' 'php7')
+license=('PHP')
+source=("https://pecl.php.net/get/apcu-$pkgver.tgz"
+        'apcu.ini')
+sha256sums=('1033530448696ee7cadec85050f6df5135fb1330072ef2a74569392acfecfbc1'
+            '18b2d904848b185bdc7c0c6a5f7c82ec809e9ed3f137cd6d3420160f4756630f')
+
+prepare() {
+	cd "$srcdir/apcu-$pkgver"
+
+	rm tests/apc_entry_002.phpt
+
+	cp -a "$srcdir/apcu-$pkgver" "$srcdir/apcu7-$pkgver"
+}
+
+build() {
+	cd "$srcdir/apcu-$pkgver"
+	phpize
+	./configure --prefix=/usr
+	make
+
+	cd "$srcdir/apcu7-$pkgver"
+	phpize7
+	./configure --prefix=/usr
+	make
+}
+
+check() {
+	export REPORT_EXIT_STATUS=1
+	export NO_INTERACTION=1
+	export SKIP_ONLINE_TESTS=1
+	export SKIP_SLOW_TESTS=1
+
+	for dir in "$srcdir/apcu"{,7}-$pkgver; do
+		pushd "$dir"
+		make test
+		popd
+	done
+}
+
+package_php-apcu() {
+	depends=(php)
+	backup=('etc/php/conf.d/apcu.ini')
+
+	cd "$srcdir/apcu-$pkgver"
+
+	make INSTALL_ROOT="$pkgdir" install
+
+	install -D -m644 "$srcdir/apcu.ini" "$pkgdir/etc/php/conf.d/apcu.ini"
+	install -D -m644 apc.php "$pkgdir/usr/share/webapps/php-apcu/apc.php"
+}
+
+package_php7-apcu() {
+	depends=(php7)
+	backup=('etc/php7/conf.d/apcu.ini')
+
+	cd "$srcdir/apcu7-$pkgver"
+
+	make INSTALL_ROOT="$pkgdir" install
+
+	install -D -m644 "$srcdir/apcu.ini" "$pkgdir/etc/php7/conf.d/apcu.ini"
+	install -D -m644 apc.php "$pkgdir/usr/share/webapps/php7-apcu/apc.php"
+}

Copied: php-apcu/repos/staging-x86_64/apcu.ini (from rev 433413, php-apcu/trunk/apcu.ini)
===================================================================
--- staging-x86_64/apcu.ini	                        (rev 0)
+++ staging-x86_64/apcu.ini	2022-01-04 17:29:50 UTC (rev 433414)
@@ -0,0 +1 @@
+;extension=apcu.so