[arch-commits] Commit in lib32-pipewire/repos (2 files)

[Jan Steffens]

    Date: Wednesday, January 5, 2022 @ 12:35:16
  Author: heftig
Revision: 1093256

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-pipewire/repos/multilib-testing-x86_64/
  lib32-pipewire/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1093255, lib32-pipewire/trunk/PKGBUILD)

----------+
 PKGBUILD |  120 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 120 insertions(+)

Copied: lib32-pipewire/repos/multilib-testing-x86_64/PKGBUILD (from rev 1093255, lib32-pipewire/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2022-01-05 12:35:16 UTC (rev 1093256)
@@ -0,0 +1,120 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=lib32-pipewire
+pkgname=(lib32-pipewire lib32-pipewire-jack lib32-pipewire-v4l2)
+pkgver=0.3.43
+pkgrel=1
+epoch=1
+pkgdesc="Low-latency audio/video router and processor - 32-bit client library"
+url="https://pipewire.org"
+license=(MIT)
+arch=(x86_64)
+makedepends=(git meson lib32-alsa-lib lib32-systemd lib32-dbus)
+_commit=07724b7aefa8a23a016727b53f4e426ecd63d248  # tags/0.3.43
+source=("git+https://gitlab.freedesktop.org/pipewire/pipewire.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd pipewire
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd pipewire
+
+  # https://gitlab.freedesktop.org/pipewire/pipewire/-/issues/1930
+  git cherry-pick -n 3c66d4600750b2039f6f969a35fce82605754b9c
+}
+
+build() {
+  local meson_options=(
+    --libdir /usr/lib32
+    -D examples=disabled
+    -D man=disabled
+    -D tests=disabled
+    -D gstreamer=disabled
+    -D gstreamer-device-provider=disabled
+    -D systemd-user-service=disabled
+    -D bluez5=disabled
+    -D jack=disabled
+    -D v4l2=disabled
+    -D libcamera=disabled
+    -D pw-cat=disabled
+    -D udevrulesdir=/usr/lib/udev/rules.d
+    -D sdl2=disabled
+    -D sndfile=disabled
+    -D libpulse=disabled
+    -D roc=disabled
+    -D avahi=disabled
+    -D echo-cancel-webrtc=disabled
+    -D libusb=disabled
+    -D session-managers=[]
+    -D raop=disabled
+    -D lv2=disabled
+  )
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+  arch-meson pipewire build "${meson_options[@]}"
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+_ver=${pkgver:0:3}
+
+package_lib32-pipewire() {
+  depends=(pipewire lib32-systemd libdbus-1.so libasound.so)
+  optdepends=('lib32-pipewire-jack: JACK support'
+              'lib32-pipewire-v4l2: V4L2 interceptor')
+  provides=(libpipewire-$_ver.so)
+
+  meson install -C build --destdir "$pkgdir"
+
+  ( cd "$pkgdir"
+
+    _pick jack usr/lib32/pipewire-$_ver/jack
+
+    _pick v4l2 usr/lib32/pipewire-$_ver/v4l2
+
+    rm -r usr/{bin,include,lib,share}
+  )
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
+}
+
+package_lib32-pipewire-jack() {
+  pkgdesc+=" - JACK support"
+  license+=(GPL2)  # libjackserver
+  depends=(pipewire-jack lib32-pipewire libpipewire-$_ver.so)
+
+  mv jack/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
+}
+
+package_lib32-pipewire-v4l2() {
+  pkgdesc+=" - V4L2 interceptor"
+  depends=(pipewire-v4l2 lib32-pipewire libpipewire-$_ver.so)
+
+  mv v4l2/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 pipewire/COPYING
+}
+
+# vim:set sw=2 et: