[arch-commits] Commit in (4 files)
Caleb Maclennan
alerque at gemini.archlinux.org
Wed Jan 5 18:30:12 UTC 2022
Date: Wednesday, January 5, 2022 @ 18:30:12
Author: alerque
Revision: 1093367
Migrate font-manager from AUR
Added:
font-manager/
font-manager/repos/
font-manager/trunk/
font-manager/trunk/PKGBUILD
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Added: font-manager/trunk/PKGBUILD
===================================================================
--- font-manager/trunk/PKGBUILD (rev 0)
+++ font-manager/trunk/PKGBUILD 2022-01-05 18:30:12 UTC (rev 1093367)
@@ -0,0 +1,54 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Joaquin <joaquingc123 at gmail dot com>
+# Contributor: Dies <JerryCasiano(at)gmail(dot)com>
+# Contributor: Joeny Ang <ang(dot)joeny(at)gmail(dot)com>
+# Contributor: Guan 'kuno' Qing <neokuno(at)gmail(dot)com>
+# Contributor: Guten Ye <ywzhaifei(at)gmail(dot)com>
+# Contributor: i_magnific0 <i_magnific0(at)yahoo(dot)com>
+# Contributor: Pavlo <pavlofreemen(at)gmail(dot)com>
+
+pkgname=font-manager
+pkgver=0.8.7
+pkgrel=3
+pkgdesc='A simple font management application for GTK+ Desktop Environments'
+url=https://fontmanager.github.io
+arch=(x86_64 i686)
+license=(GPL)
+depends=(gtk3
+ json-glib
+ libsoup
+ libxml2
+ sqlite
+ webkit2gtk)
+optdepends=(file-roller
+ libnautilus-extension)
+makedepends=(gobject-introspection
+ intltool
+ meson
+ nautilus
+ ninja
+ vala
+ yelp-tools)
+_archive="$pkgname-$pkgver"
+_url="https://github.com/FontManager/font-manager"
+source=("$_url/releases/download/$pkgver/$_archive.tar.xz"
+ "$_url/commit/f9c4621389dae5999ca9d2f3c8402c2512a9ea60.patch")
+sha256sums=('0375119e332e807c71b1da94fbab2d5d3433e62fa308181afa8558e796ce6cda'
+ '2e71c7ee6f8b691b7544afee7dd5f2200df24f8631ce26f9a9744ba413846409')
+
+prepare() {
+ cd "$_archive"
+ # see https://github.com/FontManager/font-manager/issues/240
+ patch -p1 < ../"${source[1]##*/}"
+}
+
+build() {
+ arch-meson "$_archive" build \
+ -Dnautilus=true \
+ -Dreproducible=true
+ ninja -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" ninja -C build install
+}
More information about the arch-commits
mailing list