[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, January 6, 2022 @ 21:03:10
  Author: felixonmars
Revision: 1094883

addpkg: haskell-pcg-random 0.1.3.7-1

Added:
  haskell-pcg-random/
  haskell-pcg-random/repos/
  haskell-pcg-random/trunk/
  haskell-pcg-random/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-pcg-random/trunk/PKGBUILD
===================================================================
--- haskell-pcg-random/trunk/PKGBUILD	                        (rev 0)
+++ haskell-pcg-random/trunk/PKGBUILD	2022-01-06 21:03:10 UTC (rev 1094883)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=pcg-random
+pkgname=haskell-pcg-random
+pkgver=0.1.3.7
+pkgrel=1
+pkgdesc="Haskell bindings to the PCG random number generator."
+url="http://github.com/cchalmers/pcg-random"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-entropy' 'haskell-primitive' 'haskell-random')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('e6c8c26841b5d0d6d9e2816e952e397062730fd1a0bc13cf7c3ebcba6dc1d2d0')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}