[arch-commits] Commit in haskell-logging-facade/repos (2 files)

[Felix Yan]

    Date: Thursday, January 6, 2022 @ 23:19:22
  Author: felixonmars
Revision: 1095709

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-logging-facade/repos/community-staging-x86_64/
  haskell-logging-facade/repos/community-staging-x86_64/PKGBUILD
    (from rev 1095708, haskell-logging-facade/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-logging-facade/repos/community-staging-x86_64/PKGBUILD (from rev 1095708, haskell-logging-facade/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-06 23:19:22 UTC (rev 1095709)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=logging-facade
+pkgname=haskell-logging-facade
+pkgver=0.3.1
+pkgrel=6
+pkgdesc="Simple logging abstraction that allows multiple back-ends"
+url="https://github.com/sol/logging-facade"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-call-stack')
+makedepends=('ghc')
+checkdepends=('haskell-hspec' 'haskell-hspec-discover')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('fdc95c35223db2ab99b3733f0016cea7a931e487a966dabb775608246b2c52a2ffcff508f5d0cbd50bc40c3b2e4afee18d28140b2b992037f1487870d93c93a2')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    if (( CHECKFUNC )); then
+        _opts=('--enable-tests')
+    else
+        _opts=('--disable-tests')
+    fi
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname "${_opts[@]}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}