[arch-commits] Commit in (4 files)

[Caleb Maclennan]

    Date: Friday, January 7, 2022 @ 10:39:50
  Author: alerque
Revision: 1095817

Migrate cocogitto from AUR

Added:
  cocogitto/
  cocogitto/repos/
  cocogitto/trunk/
  cocogitto/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: cocogitto/trunk/PKGBUILD
===================================================================
--- cocogitto/trunk/PKGBUILD	                        (rev 0)
+++ cocogitto/trunk/PKGBUILD	2022-01-07 10:39:50 UTC (rev 1095817)
@@ -0,0 +1,50 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com
+# Contributor: orhun <orhunparmaksiz at gmail.com>
+
+pkgname=cocogitto
+pkgver=4.0.1
+pkgrel=2
+pkgdesc="Set of CLI tools for the conventional commit and semver specifications"
+arch=(x86_64)
+url="https://github.com/$pkgname/$pkgname"
+license=(MIT)
+depends=(git
+         gcc-libs
+         libgit2
+         libgit2.so
+         zlib)
+makedepends=(cargo)
+_archive="$pkgname-$pkgver"
+source=("$url/archive/$pkgver/$_archive.tar.gz")
+sha256sums=('1a779b4c03bcb01df4ad795144516714964f3837b683df4105ed220ae79a5c2c')
+
+prepare() {
+	cd "$_archive"
+	cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+	cd "$_archive"
+	cargo build --frozen --release
+}
+
+check() {
+	cd "$_archive"
+    # Test suite is not atomic, relies on user environment such as git user configs
+    # cargo test --frozen
+}
+
+package() {
+	cd "$_archive"
+	for bin in coco cog; do
+		local target="target/release/$bin"
+		install -Dm0755 -t "$pkgdir/usr/bin/" "$target"
+		local gen="$target "
+		[[ $bin == coco ]] && gen+='--completion' || gen+='generate-completions'
+		$gen bash | install -Dm0644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/$bin"
+		$gen fish | install -Dm0644 /dev/stdin "$pkgdir/usr/share/fish/vendor_completions.d/$bin.fish"
+		$gen zsh |  install -Dm0644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_$bin"
+	done
+	install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}