[arch-commits] Commit in inkscape/repos (3 files)

Felix Yan felixonmars at gemini.archlinux.org
Fri Jan 7 11:16:20 UTC 2022


    Date: Friday, January 7, 2022 @ 11:16:20
  Author: felixonmars
Revision: 433749

archrelease: copy trunk to staging-x86_64

Added:
  inkscape/repos/staging-x86_64/
  inkscape/repos/staging-x86_64/PKGBUILD
    (from rev 433748, inkscape/trunk/PKGBUILD)
  inkscape/repos/staging-x86_64/poppler-21.11.0.patch
    (from rev 433748, inkscape/trunk/poppler-21.11.0.patch)

-----------------------+
 PKGBUILD              |   73 ++++++++++++++++++++++++++++++++++++++++++++++++
 poppler-21.11.0.patch |   26 +++++++++++++++++
 2 files changed, 99 insertions(+)

Copied: inkscape/repos/staging-x86_64/PKGBUILD (from rev 433748, inkscape/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-01-07 11:16:20 UTC (rev 433749)
@@ -0,0 +1,73 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+# Contributor: tobias <tobias at archlinux.org>
+
+pkgname=inkscape
+pkgver=1.1.1
+_tag='3bf5ae0d25c673abe152dedf4789a2d6f0cc60ff' # git rev-parse INKSCAPE_${pkgver/./_}
+pkgrel=6
+pkgdesc='Professional vector graphics editor'
+url='https://inkscape.org/'
+license=('GPL' 'LGPL')
+arch=('x86_64')
+makedepends=('cmake' 'boost' 'git')
+
+depends=(
+	'dbus-glib'
+	'double-conversion'
+	'gc'
+	'graphicsmagick'
+	'gsl'
+	'gspell'
+	'gtkmm3'
+	'lcms2'
+	'lib2geom'
+	'libcdr'
+	'libjpeg-turbo'
+	'libvisio'
+	'libxslt'
+	'poppler-glib'
+	'potrace'
+	'python'
+	'ttf-font'
+)
+
+optdepends=(
+	'fig2dev: xfig input'
+	'gvfs: import clip art'
+	'pstoedit: latex formulas'
+	'python-lxml: some extensions'
+	'python-numpy: some extensions'
+	'scour: optimized SVG output, some extensions'
+	'texlive-core: latex formulas'
+)
+
+#source=("https://media.inkscape.org/dl/resources/file/${pkgname}-${pkgver}.tar.bz2")
+source=("git+https://gitlab.com/inkscape/inkscape.git#tag=${_tag}"
+        poppler-21.11.0.patch)
+sha256sums=('SKIP'
+            '76bd1cc64ce7abef0f1758a7f05d9ca9e2cf44506318fb8ae9da029543aa1762')
+
+prepare() {
+	cd "${pkgname}"
+	git submodule init
+	git submodule update
+
+	# https://gitlab.com/inkscape/inkscape/-/merge_requests/3622
+	patch -Np1 -i ../poppler-21.11.0.patch
+}
+
+build() {
+	mkdir -p build
+	export PKG_CONFIG_PATH='/usr/lib/imagemagick6/pkgconfig'
+	cmake -H${pkgname} -Bbuild \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_INSTALL_PREFIX:PATH=/usr \
+		-DWITH_DBUS=ON \
+
+	cmake --build build
+}
+
+package() {
+	DESTDIR="${pkgdir}" cmake --build build --target install
+}

Copied: inkscape/repos/staging-x86_64/poppler-21.11.0.patch (from rev 433748, inkscape/trunk/poppler-21.11.0.patch)
===================================================================
--- staging-x86_64/poppler-21.11.0.patch	                        (rev 0)
+++ staging-x86_64/poppler-21.11.0.patch	2022-01-07 11:16:20 UTC (rev 433749)
@@ -0,0 +1,26 @@
+From ff61b5e3df3351d4ab5437181fe6d34729f4cbbb Mon Sep 17 00:00:00 2001
+From: Evangelos Foutras <evangelos at foutrelis.com>
+Date: Mon, 1 Nov 2021 21:45:38 +0200
+Subject: [PATCH] Fix build with poppler 21.11.0
+
+GfxFont::tag is now of type std::string instead of GooString *.
+---
+ src/extension/internal/pdfinput/pdf-parser.cpp | 4 ++++
+ 1 file changed, 4 insertions(+)
+
+diff --git a/src/extension/internal/pdfinput/pdf-parser.cpp b/src/extension/internal/pdfinput/pdf-parser.cpp
+index e3d04d544b..feecefa043 100644
+--- a/src/extension/internal/pdfinput/pdf-parser.cpp
++++ b/src/extension/internal/pdfinput/pdf-parser.cpp
+@@ -2169,7 +2169,11 @@ void PdfParser::opSetFont(Object args[], int /*numArgs*/)
+   }
+   if (printCommands) {
+     printf("  font: tag=%s name='%s' %g\n",
++#if POPPLER_CHECK_VERSION(21,11,0)
++	   font->getTag().c_str(),
++#else
+ 	   font->getTag()->getCString(),
++#endif
+ 	   font->getName() ? font->getName()->getCString() : "???",
+ 	   args[1].getNum());
+     fflush(stdout);



More information about the arch-commits mailing list