[arch-commits] Commit in php-snuffleupagus/repos (2 files)

[Pierre Schmitz]

    Date: Saturday, January 8, 2022 @ 09:09:33
  Author: pierre
Revision: 1096977

archrelease: copy trunk to community-staging-x86_64

Added:
  php-snuffleupagus/repos/community-staging-x86_64/
  php-snuffleupagus/repos/community-staging-x86_64/PKGBUILD
    (from rev 1096976, php-snuffleupagus/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: php-snuffleupagus/repos/community-staging-x86_64/PKGBUILD (from rev 1096976, php-snuffleupagus/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-08 09:09:33 UTC (rev 1096977)
@@ -0,0 +1,44 @@
+# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
+# Contributor: Julien (jvoisin) Voisin <julien.voisin+snuffleupagus at dustri.org>
+
+pkgname=php-snuffleupagus
+_pkgname=snuffleupagus
+pkgver=0.7.1
+pkgrel=2
+pkgdesc="Security module for PHP"
+url='https://snuffleupagus.readthedocs.io/'
+arch=('x86_64')
+license=('LGPL3')
+depends=('php')
+backup=('etc/php/conf.d/snuffleupagus.ini'
+        'etc/php/conf.d/snuffleupagus.rules')
+source=(https://github.com/jvoisin/${_pkgname}/archive/v${pkgver}/${_pkgname}-${pkgver}.tar.gz)
+b2sums=('8504721ca08e727a5a6fa58c216a5dac7be3fe6e5a98cffcb17e44a2235628c26f02afd2159e9b1fbe8e40e26bc7c4e34a4ff027ee27b8ec29cf89865dbb8514')
+
+prepare() {
+  cd ${_pkgname}-${pkgver}
+
+  # tests are incompatible with PHP 8.1
+  rm src/tests/{disable_function/disabled_functions_include_once,disable_function/disabled_functions_include_simulation,disable_function/disabled_functions_register_tick_function,disable_function/disabled_functions_require,disable_function/disabled_functions_require_once,disable_function/disabled_functions_require_simulation,strict_mode/strict_mode_enabled,stream_wrapper/stream_wrapper}.phpt
+}
+
+build() {
+  cd ${_pkgname}-${pkgver}/src
+  phpize
+  ./configure --prefix=/usr --enable-"${_pkgname}"
+  make
+}
+
+check() {
+  cd ${_pkgname}-${pkgver}/src
+  NO_INTERACTION=1 REPORT_EXIT_STATUS=1 make test
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  make -C src INSTALL_ROOT="${pkgdir}" install
+  install -D -m644 "config/default.rules" "${pkgdir}/etc/php/conf.d/${_pkgname}.rules"
+  install -D -m644 "config/${_pkgname}.ini" "${pkgdir}/etc/php/conf.d/${_pkgname}.ini"
+}
+
+# vim: ts=2 sw=2 et: