[arch-commits] Commit in rapidyaml (3 files)

[Maxime Gauduin]

    Date: Monday, January 10, 2022 @ 08:21:41
  Author: alucryd
Revision: 1098996

archrelease: copy trunk to community-x86_64

Added:
  rapidyaml/repos/
  rapidyaml/repos/community-x86_64/
  rapidyaml/repos/community-x86_64/PKGBUILD
    (from rev 1098995, rapidyaml/trunk/PKGBUILD)

----------+
 PKGBUILD |   85 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 85 insertions(+)

Copied: rapidyaml/repos/community-x86_64/PKGBUILD (from rev 1098995, rapidyaml/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2022-01-10 08:21:41 UTC (rev 1098996)
@@ -0,0 +1,85 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: xiretza <xiretza+aur at xiretza.xyz>
+
+pkgbase=rapidyaml
+pkgname=(
+  rapidyaml
+  python-rapidyaml
+)
+pkgver=0.3.0
+pkgrel=1
+pkgdesc='A library to parse and emit YAML, and do it fast'
+arch=(x86_64)
+url='https://github.com/biojppm/rapidyaml'
+license=(MIT)
+makedepends=(
+  cmake
+  git
+  ninja
+  python-setuptools
+  python-setuptools-git
+  python-setuptools-scm
+  python-cmake-build-extension
+  swig
+)
+_tag=ee581f85707da11eb25e48fc0b7f161167d58a7e
+source=(
+  git+https://github.com/biojppm/rapidyaml.git#tag=${_tag}
+  git+https://github.com/biojppm/c4core.git
+  git+https://github.com/biojppm/cmake.git
+)
+b2sums=('SKIP'
+        'SKIP'
+        'SKIP')
+
+pkgver() {
+  cd rapidyaml
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd rapidyaml
+  git submodule init
+  git config submodule.extern/c4core.url "${srcdir}"/c4core
+  git submodule update
+  cd ext/c4core
+  git submodule init
+  git config submodule.cmake.url "${srcdir}"/cmake
+  git submodule update
+}
+
+build() {
+  cmake -B build -S rapidyaml -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    -DRYML_BUILD_API=ON
+  cmake --build build
+  cd rapidyaml
+  python setup.py build
+}
+
+package_rapidyaml() {
+  depends=(
+    gcc-libs
+    glibc
+  )
+  provides=(c4core)
+
+  DESTDIR="${pkgdir}" cmake --install build
+  rm "${pkgdir}"/usr/{_ryml.so,ryml.py}
+  install -Dm 644 rapidyaml/LICENSE.txt -t "${pkgdir}"/usr/share/licenses/rapidyaml/
+}
+
+package_python-rapidyaml() {
+  depends=(
+    gcc-libs
+    glibc
+    python
+  )
+
+  cd rapidyaml
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/python-rapidyaml
+}
+
+# vim: ts=2 sw=2 et: