[arch-commits] Commit in haskell-cryptohash-sha256/repos (2 files)

[Felix Yan]

    Date: Tuesday, January 11, 2022 @ 11:48:38
  Author: felixonmars
Revision: 1100513

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-cryptohash-sha256/repos/community-staging-x86_64/
  haskell-cryptohash-sha256/repos/community-staging-x86_64/PKGBUILD
    (from rev 1100512, haskell-cryptohash-sha256/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-cryptohash-sha256/repos/community-staging-x86_64/PKGBUILD (from rev 1100512, haskell-cryptohash-sha256/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-11 11:48:38 UTC (rev 1100513)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=cryptohash-sha256
+pkgname=haskell-cryptohash-sha256
+pkgver=0.11.102.1
+pkgrel=13
+pkgdesc="Fast, pure and practical SHA-256 implementation"
+url="https://github.com/hvr/cryptohash-sha256"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base16-bytestring')
+makedepends=('ghc' 'haskell-sha' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('fb4432050ab1236fc913ba50949ee52a117b0d74509b58868e8ade69bfc6e89e1379dfea48afc76d8527d4fdbaee9dd1d2dcea4530ba95a42441491df005e78c')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -fexe
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+
+    mv "$pkgdir"/usr/bin/{,hs-}sha256sum
+}