[arch-commits] Commit in gamescope (3 files)

[Maxime Gauduin]

    Date: Tuesday, January 11, 2022 @ 21:31:25
  Author: alucryd
Revision: 1101092

archrelease: copy trunk to community-staging-x86_64

Added:
  gamescope/repos/
  gamescope/repos/community-staging-x86_64/
  gamescope/repos/community-staging-x86_64/PKGBUILD
    (from rev 1101091, gamescope/trunk/PKGBUILD)

----------+
 PKGBUILD |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

Copied: gamescope/repos/community-staging-x86_64/PKGBUILD (from rev 1101091, gamescope/trunk/PKGBUILD)
===================================================================
--- repos/community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-staging-x86_64/PKGBUILD	2022-01-11 21:31:25 UTC (rev 1101092)
@@ -0,0 +1,73 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: Giancarlo Razzolini <grazzolini at archlinux.org>
+# Contributor: Samuel "scrufulufugus" Monson <smonson at irbash.net>
+# Contributor: PedroHLC <root at pedrohlc.com>
+
+pkgname=gamescope
+pkgver=3.11.0.beta2
+pkgrel=1
+pkgdesc='SteamOS session compositing window manager'
+arch=(x86_64)
+url=https://github.com/Plagman/gamescope
+license=(BSD)
+depends=(
+  gcc-libs
+  glibc
+  libcap.so
+  libdrm
+  libliftoff.so
+  libpipewire-0.3.so
+  libvulkan.so
+  libwlroots.so
+  libx11
+  libxcomposite
+  libxdamage
+  libxext
+  libxfixes
+  libxkbcommon.so
+  libxrender
+  libxres
+  libxtst
+  libxxf86vm
+  sdl2
+  vulkan-icd-loader
+  wayland
+  wayland-protocols
+  wlroots
+  xorg-server-xwayland
+)
+makedepends=(
+  git
+  glslang
+  meson
+  ninja
+  vulkan-headers
+)
+_tag=45b4bb8384b2c21e232fc8dfe1906fd3cc4c7687
+source=(git+https://github.com/Plagman/gamescope.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  cd gamescope
+  meson subprojects download
+}
+
+pkgver() {
+  cd gamescope
+  git describe --tags | sed 's/-/./'
+}
+
+build() {
+  export LDFLAGS="$LDFLAGS -lrt"
+  arch-meson gamescope build \
+    -Dforce_fallback_for= \
+    -Dpipewire=enabled
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 gamescope/LICENSE -t "${pkgdir}"/usr/share/licenses/gamescope/
+}
+
+# vim: ts=2 sw=2 et: