[arch-commits] Commit in gobject-introspection/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Thursday, January 13, 2022 @ 15:54:09
  Author: heftig
Revision: 434409

archrelease: copy trunk to extra-x86_64

Added:
  gobject-introspection/repos/extra-x86_64/PKGBUILD
    (from rev 434407, gobject-introspection/trunk/PKGBUILD)
Deleted:
  gobject-introspection/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  138 +++++++++++++++++++++++++++++++++----------------------------
 1 file changed, 76 insertions(+), 62 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-01-13 15:54:04 UTC (rev 434408)
+++ PKGBUILD	2022-01-13 15:54:09 UTC (rev 434409)
@@ -1,62 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Jan de Groot <jgc at archlinux.org>
-
-pkgbase=gobject-introspection
-pkgname=(gobject-introspection gobject-introspection-runtime)
-pkgver=1.70.0
-pkgrel=4
-pkgdesc="Introspection system for GObject-based libraries"
-url="https://wiki.gnome.org/Projects/GObjectIntrospection"
-arch=(x86_64)
-license=(LGPL GPL)
-depends=(python-mako python-markdown)
-_glibver=2.70.1
-makedepends=(cairo git gtk-doc python-sphinx meson "glib2=$_glibver")
-options=(!emptydirs)
-_commit=4502dd33da995e5e9e6d73aa996cf42e92c9e217  # tags/1.70.0^0
-source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit"
-        "git+https://gitlab.gnome.org/GNOME/glib.git?signed#tag=$_glibver")
-sha512sums=('SKIP'
-            'SKIP')
-validpgpkeys=('923B7025EE03C1C59F42684CF0942E894B2EAFA0') # Philip Withnall <philip at tecnocode.co.uk>
-
-pkgver() {
-  cd $pkgbase
-  git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
-  cd $pkgbase
-}
-  
-build() {
-  arch-meson $pkgbase build \
-    -D gtk_doc=true \
-    -D glib_src_dir="$srcdir/glib"
-  meson compile -C build
-}
-
-check() {
-  meson test -C build
-}
-
-package_gobject-introspection() {
-  depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
-
-  meson install -C build --destdir "$pkgdir"
-
-  python -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
-  python -O -m compileall -d /usr/lib/$pkgbase "$pkgdir/usr/lib/$pkgbase"
-
-### Split runtime
-  mkdir -p "$srcdir/runtime/lib"
-  mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
-}
-
-package_gobject-introspection-runtime() {
-  pkgdesc+=" (runtime library)"
-  depends=(glib2)
-  provides+=(libgirepository-1.0.so)
-
-  mv "$srcdir/runtime" "$pkgdir/usr"
-}

Copied: gobject-introspection/repos/extra-x86_64/PKGBUILD (from rev 434407, gobject-introspection/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-01-13 15:54:09 UTC (rev 434409)
@@ -0,0 +1,76 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gobject-introspection
+pkgname=(gobject-introspection gobject-introspection-runtime)
+pkgver=1.70.0
+pkgrel=5
+pkgdesc="Introspection system for GObject-based libraries"
+url="https://wiki.gnome.org/Projects/GObjectIntrospection"
+arch=(x86_64)
+license=(LGPL GPL)
+depends=(python-mako python-markdown)
+_glibver=2.70.2
+makedepends=(cairo git gtk-doc python-sphinx meson "glib2=$_glibver")
+options=(!emptydirs)
+_commit=4502dd33da995e5e9e6d73aa996cf42e92c9e217  # tags/1.70.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/glib.git?signed#tag=$_glibver")
+sha512sums=('SKIP'
+            'SKIP')
+validpgpkeys=('923B7025EE03C1C59F42684CF0942E894B2EAFA0') # Philip Withnall <philip at tecnocode.co.uk>
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+
+  # Fix build with meson 0.61.0
+  git cherry-pick -n 827494d6415b696a effb1e09dee263cd
+}
+  
+build() {
+  arch-meson $pkgbase build \
+    -D gtk_doc=true \
+    -D glib_src_dir="$srcdir/glib"
+  meson compile -C build
+}
+
+check() {
+  meson test -C build
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_gobject-introspection() {
+  depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
+
+  meson install -C build --destdir "$pkgdir"
+
+  cd "$pkgdir"
+
+  python -m compileall -d /usr/lib/$pkgbase usr/lib/$pkgbase
+  python -O -m compileall -d /usr/lib/$pkgbase usr/lib/$pkgbase
+
+  _pick runtime usr/lib/lib*
+  _pick runtime usr/lib/girepository-*
+}
+
+package_gobject-introspection-runtime() {
+  pkgdesc+=" (runtime library)"
+  depends=(glib2)
+  provides+=(libgirepository-1.0.so)
+
+  mv runtime/* "$pkgdir"
+}