[arch-commits] Commit in ruby-nio4r/repos (2 files)
Christian Hesse
eworm at gemini.archlinux.org
Thu Jan 13 21:29:19 UTC 2022
Date: Thursday, January 13, 2022 @ 21:29:19
Author: eworm
Revision: 1102963
archrelease: copy trunk to community-testing-x86_64
Added:
ruby-nio4r/repos/community-testing-x86_64/
ruby-nio4r/repos/community-testing-x86_64/PKGBUILD
(from rev 1102962, ruby-nio4r/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: ruby-nio4r/repos/community-testing-x86_64/PKGBUILD (from rev 1102962, ruby-nio4r/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2022-01-13 21:29:19 UTC (rev 1102963)
@@ -0,0 +1,45 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
+
+_gemname=nio4r
+pkgname=ruby-${_gemname}
+pkgver=2.5.7
+pkgrel=2
+pkgdesc='Abstract, cross-platform stateful I/O selector API for Ruby'
+url='https://github.com/celluloid/nio4r'
+arch=('x86_64')
+license=('MIT')
+depends=('ruby')
+makedepends=('ruby-rdoc' 'git')
+options=('!emptydirs')
+source=(https://github.com/celluloid/nio4r/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('da04bb10d604aee02cdbb92377b66de62bc28421a834fa190f29c07b9230e51ee1c59814c69f2ebbd3a67f3d5b5444301896742bde1c19546a764d8030c276b8')
+b2sums=('7927671c883d0cfb937fcc4b05e8013c82c0117a560b691c9409fed91073cac1e0a97d1bf50c07bcfb080fe16a0cf634e010f731e99fff047a984303f9074200')
+
+prepare() {
+ cd ${_gemname}-${pkgver}
+ sed 's|git ls-files|find|' -i ${_gemname}.gemspec
+}
+
+build() {
+ cd ${_gemname}-${pkgver}
+ gem build ${_gemname}.gemspec
+}
+
+package() {
+ cd ${_gemname}-${pkgver}
+ local _gemdir="$(gem env gemdir)"
+ gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
+ -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
+
+ install -Dm 644 README.md CHANGES.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+ install -Dm 644 README.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+ cp -r examples "${pkgdir}/usr/share/doc/${pkgname}"
+
+ cd "${pkgdir}/${_gemdir}"
+ rm -rf cache gems/${_gemname}-${pkgver}/{ext,lib/*/*.so} \
+ extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out} \
+ "${pkgdir}/${_gemdir}/doc/${_gemname}-${pkgver}/ri/ext/"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list