[arch-commits] Commit in haskell-persistent-test/repos (2 files)

[Felix Yan]

    Date: Friday, January 14, 2022 @ 23:25:48
  Author: felixonmars
Revision: 1103634

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent-test/repos/community-staging-x86_64/
  haskell-persistent-test/repos/community-staging-x86_64/PKGBUILD
    (from rev 1103633, haskell-persistent-test/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-persistent-test/repos/community-staging-x86_64/PKGBUILD (from rev 1103633, haskell-persistent-test/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-14 23:25:48 UTC (rev 1103634)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=persistent-test
+pkgname=haskell-persistent-test
+pkgver=2.13.0.3
+pkgrel=80
+pkgdesc="Tests for Persistent"
+url="https://github.com/yesodweb/persistent"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-persistent' 'haskell-aeson' 'haskell-blaze-html' 'haskell-conduit'
+         'haskell-hspec' 'haskell-hspec-expectations' 'haskell-hunit' 'haskell-monad-control'
+         'haskell-monad-logger' 'haskell-path-pieces' 'haskell-quickcheck'
+         'haskell-quickcheck-instances' 'haskell-random' 'haskell-resourcet'
+         'haskell-transformers-base' 'haskell-unliftio' 'haskell-unliftio-core'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-hspec' 'haskell-http-api-data' 'haskell-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('794c7f22a7d44b7fa0c2d05d936ce68c6e13927abc909bfe3784228e9750103576417e6b8400bb8ea34002a17e59a4a5dd73626035a4aaaadc81b02a1d9059c2')
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}