[arch-commits] Commit in efivar/repos (testing-x86_64 testing-x86_64/PKGBUILD)
David Runge
dvzrv at gemini.archlinux.org
Mon Jan 17 18:01:52 UTC 2022
Date: Monday, January 17, 2022 @ 18:01:52
Author: dvzrv
Revision: 434616
archrelease: copy trunk to testing-x86_64
Added:
efivar/repos/testing-x86_64/
efivar/repos/testing-x86_64/PKGBUILD
(from rev 434615, efivar/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: efivar/repos/testing-x86_64/PKGBUILD (from rev 434615, efivar/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2022-01-17 18:01:52 UTC (rev 434616)
@@ -0,0 +1,52 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+# Contributor: Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
+
+pkgname=efivar
+pkgdesc="Tools and libraries to work with EFI variables"
+pkgver=38
+pkgrel=2
+arch=(x86_64)
+url="https://github.com/rhboot/efivar"
+license=(LGPL2.1)
+depends=(glibc)
+makedepends=(git mandoc)
+checkdepends=(grub)
+provides=(libefiboot.so libefisec.so libefivar.so)
+# LTO has the linker segfaulting with binutils < 2.38.0: https://github.com/rhboot/efivar/issues/196
+options=(!lto)
+source=(
+ "git+https://github.com/rhinstaller/efivar.git#tag=${pkgver}?signed"
+ "${pkgname}-38-ld_t.patch::https://github.com/rhboot/efivar/pull/201/commits/197a0874ea4010061b98b4b55eff65b33b1cd741.patch"
+)
+sha512sums=('SKIP'
+ '568bc88b182875c37479c49b3dbf5b8ee6edf8090f940176e67c9aa28dd2ff6f417c70b2bef6b5df99ada2afa33db3efd295ba9de5d68b3ecc5ce1dc3361d042')
+b2sums=('SKIP'
+ 'ccddc04ab83d4dcf570d5a89e43fc27d36e2010513b36d9eb2fcdea71ceb5dba96a064a1cbca9ffdecf17fb5b9cb22cfe89eae4ee3a188547a4ab6fa6b4e2983')
+validpgpkeys=('B00B48BC731AA8840FED9FB0EED266B70F4FEF10') # Peter Jones <pjones at redhat.com>
+
+prepare() {
+ cd "${pkgname}"
+ # fix issues with linker scripts: https://github.com/rhboot/efivar/pull/201
+ patch -Np1 -i ../"${pkgname}-38-ld_t.patch"
+}
+
+build() {
+ # disable -Werror by default by setting ERRORS to empty string
+ make ERRORS='' all -C "${pkgname}"
+}
+
+check() {
+ make GRUB_PREFIX=grub test -k -C "${pkgname}" || echo "grub related tests are flaky"
+}
+
+package() {
+ make DESTDIR="${pkgdir}/" \
+ libdir=/usr/lib/ \
+ bindir=/usr/bin/ \
+ mandir=/usr/share/man/ \
+ includedir=/usr/include/ \
+ install -j1 V=1 \
+ -C "${pkgname}"
+ install -vDm 644 "${pkgname}/"{README.md,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
More information about the arch-commits
mailing list