[arch-commits] Commit in mutter/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Monday, January 17, 2022 @ 19:22:11
  Author: arojas
Revision: 434626

archrelease: copy trunk to staging-x86_64

Added:
  mutter/repos/staging-x86_64/
  mutter/repos/staging-x86_64/PKGBUILD
    (from rev 434625, mutter/trunk/PKGBUILD)

----------+
 PKGBUILD |   70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

Copied: mutter/repos/staging-x86_64/PKGBUILD (from rev 434625, mutter/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-01-17 19:22:11 UTC (rev 434626)
@@ -0,0 +1,70 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=41.3
+pkgrel=2
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
+         libcanberra startup-notification zenity libsm gnome-desktop upower
+         libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
+         xorg-xwayland graphene libxkbfile libsysprof-capture)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server
+             wayland-protocols sysprof)
+checkdepends=(xorg-server-xvfb pipewire-media-session python-dbusmock)
+provides=(libmutter-9.so)
+groups=(gnome)
+_commit=f51ad2911419ee2ab88b5548581227a57d0fd987  # tags/41.3^0
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd mutter
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd mutter
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+
+  arch-meson mutter build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D installed_tests=false
+  meson compile -C build
+}
+
+_check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  pipewire &
+  _p1=$!
+
+  pipewire-media-session &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  meson test -C build --print-errorlogs
+)
+
+check() {
+  dbus-run-session xvfb-run -s '-nolisten local +iglx -noreset' \
+    bash -c "$(declare -f _check); _check"
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim:set sw=2 et: