[arch-commits] Commit in mutter6/repos (2 files)

[Antonio Rojas]

    Date: Monday, January 17, 2022 @ 19:43:17
  Author: arojas
Revision: 1108127

archrelease: copy trunk to community-staging-x86_64

Added:
  mutter6/repos/community-staging-x86_64/
  mutter6/repos/community-staging-x86_64/PKGBUILD
    (from rev 1108126, mutter6/trunk/PKGBUILD)

----------+
 PKGBUILD |   70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

Copied: mutter6/repos/community-staging-x86_64/PKGBUILD (from rev 1108126, mutter6/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-17 19:43:17 UTC (rev 1108127)
@@ -0,0 +1,70 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter6
+pkgver=3.36.9
+pkgrel=2
+pkgdesc='A window manager for GNOME'
+url=https://gitlab.gnome.org/GNOME/mutter
+arch=(x86_64)
+license=(GPL2)
+depends=(
+  dconf
+  gnome-desktop
+  gnome-settings-daemon
+  gobject-introspection-runtime
+  gsettings-desktop-schemas
+  libcanberra
+  libgraphene-1.0.so
+  libgudev
+  libinput
+  libsm
+  libxkbcommon-x11
+  libxkbfile
+  pipewire
+  startup-notification
+  upower
+  xorg-server-xwayland
+  zenity
+)
+makedepends=(
+  egl-wayland
+  git
+  gobject-introspection
+  meson
+  wayland-protocols
+  xorg-server
+)
+checkdepends=(xorg-server-xvfb)
+provides=(libmutter-6.so)
+_tag=197d774e0b5f56121b7fea3d959e79b2f87450c5
+source=(git+https://gitlab.gnome.org/GNOME/mutter.git#tag=${_tag})
+sha256sums=('SKIP')
+
+pkgver() {
+  cd mutter
+
+  git describe --tags
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+  arch-meson mutter build \
+    --libexecdir /usr/lib/mutter-6 \
+    -D egl_device=true \
+    -D installed_tests=false \
+    -D profiler=false \
+    -D wayland_eglstream=true \
+    -D xwayland_initfd=disabled
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  rm -rf "${pkgdir}"/usr/{bin,share}
+}
+
+# vim: ts=2 sw=2 et: