[arch-commits] Commit in pymol/trunk (PKGBUILD)

[Caleb Maclennan]

    Date: Tuesday, January 18, 2022 @ 12:21:12
  Author: alerque
Revision: 1108674

upgpkg: pymol 2.5.0-3; adopt, fix reproducability

Modified:
  pymol/trunk/PKGBUILD

----------+
 PKGBUILD |   66 ++++++++++++++++++++++++++++++++++++-------------------------
 1 file changed, 39 insertions(+), 27 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-01-18 12:15:47 UTC (rev 1108673)
+++ PKGBUILD	2022-01-18 12:21:12 UTC (rev 1108674)
@@ -1,44 +1,56 @@
-# Maintainer: Evgeniy Alekseev <arcanis at archlinux dot org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Evgeniy Alekseev <arcanis at archlinux dot org>
 # Contributor: graysky
 # Contributor: Tomasz Żok <tomasz dot zok at gmail dot com>
 
 pkgname=pymol
+_project=pymol-open-source
 pkgver=2.5.0
-pkgrel=2
-pkgdesc="Molecular visualization system on an Open Source foundation"
-arch=('x86_64')
-url="https://pymol.org/"
-license=('custom')
-depends=('freetype2' 'glew' 'glm' 'glut' 'netcdf' 'netcdf-cxx' 'python-numpy' 'tcsh')
-makedepends=('desktop-file-utils' 'gendesk' 'libmmtf' 'msgpack-c')
+pkgrel=3
+pkgdesc='Molecular visualization system on an Open Source foundation'
+arch=(x86_64)
+url=https://pymol.org
+license=(custom)
+depends=(freetype2
+         glew
+         glm
+         glut
+         netcdf
+         netcdf-cxx
+         python-numpy
+         tcsh)
+makedepends=(desktop-file-utils
+             gendesk
+             libmmtf
+             msgpack-c)
 optdepends=('python-pyqt5: Qt5 based UI')
-source=("$pkgname-$pkgver.tar.gz::https://github.com/schrodinger/pymol-open-source/archive/v${pkgver}.tar.gz"
-        ${pkgname}.png::"https://c.fsdn.com/allura/p/pymol/icon")
-sha512sums=('19f21b8f735fda5314abf202d56f3c81c7251bf6ef0df73ccee534d9c08035f4ef6155ffb68e09d7717a0fb5ba7289bbfa440691bea4cec0de7199c9e858ea91'
-            '39917c1dc80cd6a59e8f6b3ea49a59491eaf23d14e32ac264f6d71f33007f686deb6a66e50e7f20ef9df5337038e3572b018633c361460d5ee0c1d8f0a8259d1')
+_archive="$_project-$pkgver"
+source=("https://github.com/schrodinger/pymol-open-source/archive/v$pkgver/$_archive.tar.gz"
+        "$pkgname.png::https://c.fsdn.com/allura/p/pymol/icon")
+sha256sums=('aa828bf5719bd9a14510118a93182a6e0cadc03a574ba1e327e1e9780a0e80b3'
+            '0ea81faaf336becc669a193777d0dca55475d303d1236b57df25cf67ff7c2bcd')
 changelog=ChangeLog
 
 prepare() {
-  # create desktop file
-  gendesk -f -n --pkgname "${pkgname}" --pkgdesc "${pkgdesc}" \
-          --name="PyMOL Molecular Graphics System" \
-          --categories="Science;Chemistry"
+	# create desktop file
+	gendesk -f -n --pkgname "$pkgname" --pkgdesc "$pkgdesc" \
+			--name="PyMOL Molecular Graphics System" \
+			--categories="Science;Chemistry"
 
-  # suppress non-zero exit code that breaks makepkg
-  sed -i '/sys.exit/ s,2,0,' "${srcdir}/${pkgname}-open-source-${pkgver}/setup.py"
+	cd "$_archive"
+	# suppress non-zero exit code that breaks makepkg
+	sed -i -e '/sys.exit/ s,2,0,' setup.py
 }
 
 build() {
-  cd "${srcdir}/${pkgname}-open-source-${pkgver}"
-  python setup.py build
+	cd "$_archive"
+	python setup.py build
 }
 
 package() {
-  cd "${srcdir}/${pkgname}-open-source-${pkgver}"
-  python setup.py install --prefix=/usr --root="${pkgdir}"
-  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-  install -Dm644 "${srcdir}/pymol.desktop" "${pkgdir}/usr/share/applications/pymol.desktop"
-  install -Dm644 "${srcdir}/pymol.png" "${pkgdir}/usr/share/pixmaps/pymol.png"
+	install -Dm0644 -t "$pkgdir/usr/share/applications/" "$pkgname.desktop"
+	install -Dm0644 -t "$pkgdir/usr/share/pixmaps/" "$pkgname.png"
+	cd "$_archive"
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
 }
-
-# vim:set ts=2 sw=2 et: