[arch-commits] Commit in dhall-docs/repos (2 files)

[Felix Yan]

    Date: Tuesday, January 18, 2022 @ 16:30:40
  Author: felixonmars
Revision: 1109214

archrelease: copy trunk to community-staging-x86_64

Added:
  dhall-docs/repos/community-staging-x86_64/
  dhall-docs/repos/community-staging-x86_64/PKGBUILD
    (from rev 1109213, dhall-docs/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: dhall-docs/repos/community-staging-x86_64/PKGBUILD (from rev 1109213, dhall-docs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-18 16:30:40 UTC (rev 1109214)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=dhall-docs
+pkgver=1.0.8
+pkgrel=12
+pkgdesc="Generate HTML docs from a dhall package"
+url="https://github.com/dhall-lang/dhall-haskell/tree/master/dhall-docs"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base16-bytestring' 'haskell-cryptohash-sha256' 'dhall'
+         'haskell-file-embed' 'haskell-lens-family-core' 'haskell-lucid' 'haskell-megaparsec'
+         'haskell-mmark' 'haskell-optparse-applicative' 'haskell-path' 'haskell-path-io'
+         'haskell-prettyprinter')
+makedepends=('ghc' 'haskell-doctest' 'haskell-foldl' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-silver' 'haskell-turtle')
+source=("https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz")
+sha512sums=('550bbc31c01297f48680fe931387f6c7657179c3469170125d2c0690fccb7c1b635aad727e7d1531a1011a80859e9fc753a380b9e1392adbb8374e25795c6a32')
+
+build() {
+  cd $pkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $pkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}