[arch-commits] Commit in python-click-option-group/repos (2 files)

David Runge dvzrv at gemini.archlinux.org
Thu Jan 20 19:04:25 UTC 2022


    Date: Thursday, January 20, 2022 @ 19:04:25
  Author: dvzrv
Revision: 1111536

archrelease: copy trunk to community-any

Added:
  python-click-option-group/repos/community-any/
  python-click-option-group/repos/community-any/PKGBUILD
    (from rev 1111535, python-click-option-group/trunk/PKGBUILD)

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Copied: python-click-option-group/repos/community-any/PKGBUILD (from rev 1111535, python-click-option-group/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-01-20 19:04:25 UTC (rev 1111536)
@@ -0,0 +1,36 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=click-option-group
+pkgname=python-click-option-group
+pkgver=0.5.3
+pkgrel=2
+pkgdesc="Option groups missing in Click"
+arch=(any)
+url="https://github.com/click-contrib/click-option-group"
+license=(BSD)
+depends=(python-click)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest)
+# no tests in sdist tarball: https://github.com/click-contrib/click-option-group/issues/39
+# source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
+source=("${_name}-v${pkgver}.tar.gz::https://github.com/click-contrib/click-option-group/archive/refs/tags/v${pkgver}.tar.gz")
+sha512sums=('9b9861c84d3df206df165bd43dd8ec9544ae646cb0a1cf9d4457a837df9517c952e54aafedf4cf095036ac842b936d7685c6949272d8cef95b28e27ea59c8057')
+b2sums=('7917894b34fcfb34955a44b4971a662a4960ba9e04f1709ec9669585b004345dc0021d2f40eec69b999e22a05ee367510c17e8b739ee563f287a046815c27e52')
+
+build() {
+  cd "$_name-$pkgver"
+  python setup.py build
+}
+
+check() {
+  cd "$_name-$pkgver"
+  export PYTHONPATH="build:${PYTHONPATH}"
+  pytest -v
+}
+
+package() {
+  cd "$_name-$pkgver"
+  python setup.py install --optimize=1 --root="${pkgdir}"
+  install -vDm 644 {CHANGELOG,README}.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}



More information about the arch-commits mailing list