[arch-commits] Commit in haskell-shakespeare/repos (2 files)

[Felix Yan]

    Date: Friday, January 21, 2022 @ 19:55:07
  Author: felixonmars
Revision: 1112524

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-shakespeare/repos/community-staging-x86_64/
  haskell-shakespeare/repos/community-staging-x86_64/PKGBUILD
    (from rev 1112523, haskell-shakespeare/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-shakespeare/repos/community-staging-x86_64/PKGBUILD (from rev 1112523, haskell-shakespeare/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-21 19:55:07 UTC (rev 1112524)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=shakespeare
+pkgname=haskell-shakespeare
+pkgver=2.0.25.1
+pkgrel=6
+pkgdesc="A toolkit for making compile-time interpolated templates"
+url="https://www.yesodweb.com/book/shakespearean-templates"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-blaze-html' 'haskell-blaze-markup'
+         'haskell-scientific' 'haskell-th-lift' 'haskell-unordered-containers'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b93091d00dfabdb352c41967db59ce48522a5d68bb8bb92c2409d57c70b3ea7ff33d648c10ce484fa552d3beddf90c40872141e6a1ab1f9aa33458921442d777')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-test_roy -f-test_coffee -f-test_export
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}