[arch-commits] Commit in haskell-aeson-qq/repos (2 files)

[Felix Yan]

    Date: Friday, January 21, 2022 @ 19:56:48
  Author: felixonmars
Revision: 1112530

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-aeson-qq/repos/community-staging-x86_64/
  haskell-aeson-qq/repos/community-staging-x86_64/PKGBUILD
    (from rev 1112529, haskell-aeson-qq/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-aeson-qq/repos/community-staging-x86_64/PKGBUILD (from rev 1112529, haskell-aeson-qq/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-21 19:56:48 UTC (rev 1112530)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=aeson-qq
+pkgname=haskell-aeson-qq
+pkgver=0.8.4
+pkgrel=16
+pkgdesc="JSON quasiquoter for Haskell"
+url="https://github.com/sol/aeson-qq"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base-compat' 'haskell-src-meta'
+         'haskell-scientific' 'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hspec-discover')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('24281e5e6b127e444a87c388c8f39e2afce2c33a31c9b299021108b12e5a510875140a2b6912a14a4676ded405a1ef9f2bddc5fc179bb6d81d42feed4731f6b1')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}