[arch-commits] Commit in python-pywlroots/repos (2 files)
David Runge
dvzrv at gemini.archlinux.org
Sun Jan 23 14:58:59 UTC 2022
Date: Sunday, January 23, 2022 @ 14:58:59
Author: dvzrv
Revision: 1113608
archrelease: copy trunk to community-staging-x86_64
Added:
python-pywlroots/repos/community-staging-x86_64/
python-pywlroots/repos/community-staging-x86_64/PKGBUILD
(from rev 1113607, python-pywlroots/trunk/PKGBUILD)
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Copied: python-pywlroots/repos/community-staging-x86_64/PKGBUILD (from rev 1113607, python-pywlroots/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-01-23 14:58:59 UTC (rev 1113608)
@@ -0,0 +1,41 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=pywlroots
+pkgname=python-pywlroots
+pkgver=0.15.3
+pkgrel=1
+pkgdesc="Python binding to the wlroots library using cffi"
+arch=(x86_64)
+url="https://github.com/flacjacket/pywlroots"
+license=(custom:UIUC)
+depends=(glibc python-cffi python-pywayland python-xkbcommon wlroots
+libwlroots.so)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest)
+provides=(pywlroots)
+conflicts=(pywlroots)
+replaces=(pywlroots)
+source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
+sha512sums=('518199f3857b5b4091c39e3a5a4a806e11c35305ca687a967b19d276990eb6472e5963e4553379d97ff1d5dc78c8552935bb87bed911378f3e5be8aa1d0b850d')
+b2sums=('f4dbb7ca5efcb9daaecb252dfb617bb27683d3c0c6a1f792dd93fcff46d546d728cfff8e01911793b07123e4051cba6b151c80ea948857736ada5fe5215ece4b')
+
+build() {
+ cd "${_name}-$pkgver"
+ python wlroots/ffi_build.py
+ python setup.py build
+}
+
+check() {
+ local _py_ver=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+
+ cd "${_name}-$pkgver"
+ export PYTHONPATH="build/lib.linux-${CARCH}-${_py_ver}:${PYTHONPATH}"
+ pytest -v
+}
+
+package() {
+ cd "${_name}-$pkgver"
+ python setup.py install --optimize=1 --root="${pkgdir}"
+ install -vDm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+ install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
More information about the arch-commits
mailing list