[arch-commits] Commit in dolphin-emu/repos (3 files)

[Maxime Gauduin]

    Date: Sunday, January 23, 2022 @ 15:38:25
  Author: alucryd
Revision: 1113628

archrelease: copy trunk to community-staging-x86_64

Added:
  dolphin-emu/repos/community-staging-x86_64/
  dolphin-emu/repos/community-staging-x86_64/PKGBUILD
    (from rev 1113627, dolphin-emu/trunk/PKGBUILD)
  dolphin-emu/repos/community-staging-x86_64/dolphin-emu-system-libmgba.patch
    (from rev 1113627, dolphin-emu/trunk/dolphin-emu-system-libmgba.patch)

----------------------------------+
 PKGBUILD                         |   87 +++++++++++++++++++++++++++++++++++++
 dolphin-emu-system-libmgba.patch |   24 ++++++++++
 2 files changed, 111 insertions(+)

Copied: dolphin-emu/repos/community-staging-x86_64/PKGBUILD (from rev 1113627, dolphin-emu/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-23 15:38:25 UTC (rev 1113628)
@@ -0,0 +1,87 @@
+# Maintainer: schuay <jakob.gruber at gmail.com>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Jeremy Newton (Mystro256) <alexjnewt at gmail.com>
+
+pkgname=dolphin-emu
+pkgver=5.0.r15445.db02b50d2e
+pkgrel=3
+epoch=1
+pkgdesc='A Gamecube / Wii / Triforce emulator'
+arch=(x86_64)
+url=https://dolphin-emu.org
+license=(GPL2)
+depends=(
+  alsa-lib
+  bluez-libs
+  enet
+  gcc-libs
+  glibc
+  hidapi
+  libavcodec.so
+  libavformat.so
+  libavutil.so
+  libcurl.so
+  libevdev
+  #libfmt.so
+  libgl
+  #libmgba
+  libminiupnpc.so
+  libpng
+  libpulse
+  libswscale.so
+  libudev.so
+  libusb-1.0.so
+  libx11
+  libxi
+  libxrandr
+  lzo
+  mbedtls
+  pugixml
+  qt5-base
+  sfml
+  zlib
+)
+makedepends=(
+  cmake
+  git
+  ninja
+  python
+)
+optdepends=('pulseaudio: PulseAudio backend')
+options=(!emptydirs)
+_commit=db02b50d2ecdfbbc21e19aadc57253c353069f77
+source=(
+  dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=${_commit}
+  dolphin-emu-system-libmgba.patch
+)
+b2sums=('SKIP'
+        '004692abcfa3a0a10996afba3a8fe71627300224a6f96cc5b6c6183c32d5f7bd1ece36775cd2642a0c4d7fc9225f72da39063cc68ff089e8d01685a2fbbd6957')
+
+prepare() {
+  cd dolphin-emu
+  #patch -Np1 -i ../dolphin-emu-system-libmgba.patch
+}
+
+pkgver() {
+  cd dolphin-emu
+  git describe | sed 's/-/.r/; s/-g/./'
+}
+
+build() {
+  export CXXFLAGS+=" -fpermissive"
+  cmake -S dolphin-emu -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DDISTRIBUTOR=archlinux.org \
+    -DUSE_MGBA=OFF \
+    -DUSE_SHARED_ENET=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build
+  install -Dm 644 dolphin-emu/Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
+  rm -rf "${pkgdir}"/usr/{include,lib/libdiscord-rpc.a}
+}
+
+# vim: ts=2 sw=2 et:

Copied: dolphin-emu/repos/community-staging-x86_64/dolphin-emu-system-libmgba.patch (from rev 1113627, dolphin-emu/trunk/dolphin-emu-system-libmgba.patch)
===================================================================
--- community-staging-x86_64/dolphin-emu-system-libmgba.patch	                        (rev 0)
+++ community-staging-x86_64/dolphin-emu-system-libmgba.patch	2022-01-23 15:38:25 UTC (rev 1113628)
@@ -0,0 +1,24 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index d446e0b465..07fd13db85 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -831,8 +831,17 @@ if(NOT ENABLE_QT)
+   set(USE_MGBA 0)
+ endif()
+ if(USE_MGBA)
+-  message(STATUS "Using static libmgba from Externals")
+-  add_subdirectory(Externals/mGBA)
++  if (SYSTEM_LIBMGBA)
++    find_library(MGBA_LIBRARY mgba)
++    add_library(mgba ${MGBA_LIBRARY})
++    add_library(mGBA::mgba ALIAS mgba)
++    set_target_properties(mgba PROPERTIES LINKER_LANGUAGE C)
++    message(STATUS "Found libmgba: ${MGBA_LIBRARY}")
++    message(STATUS "Using shared libmgba")
++  else()
++    message(STATUS "Using static libmgba from Externals")
++    add_subdirectory(Externals/mGBA)
++  endif()
+ endif()
+
+ find_package(SYSTEMD)