[arch-commits] Commit in lib32-fluidsynth/repos (2 files)

[David Runge]

    Date: Sunday, January 23, 2022 @ 15:39:31
  Author: dvzrv
Revision: 1113632

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-fluidsynth/repos/multilib-staging-x86_64/
  lib32-fluidsynth/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1113631, lib32-fluidsynth/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: lib32-fluidsynth/repos/multilib-staging-x86_64/PKGBUILD (from rev 1113631, lib32-fluidsynth/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-01-23 15:39:31 UTC (rev 1113632)
@@ -0,0 +1,66 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: David Runge <dvzrv at archlinux.org>
+# Contributor: carstene1ns <arch.carsten at teibes.de>
+# Contributor: Giuseppe Calà  <jiveaxe at gmail.com>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+pkgname=lib32-fluidsynth
+_name=fluidsynth
+pkgver=2.2.5
+pkgrel=1
+pkgdesc='A real-time software synthesizer based on the SoundFont 2 specifications'
+arch=(x86_64)
+url="https://www.fluidsynth.org/"
+license=(LGPL2.1)
+depends=(
+  fluidsynth=${pkgver}
+  lib32-glibc
+  lib32-libpulse
+  lib32-readline
+  lib32-sdl2
+)
+makedepends=(
+  cmake
+  lib32-alsa-lib
+  lib32-dbus
+  lib32-glib2
+  lib32-jack
+  lib32-ladspa
+  lib32-libinstpatch
+  lib32-libsndfile
+  lib32-portaudio
+)
+optdepends=('pulseaudio: PulseAudio sound support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/${_name}/${_name}/archive/v${pkgver}.tar.gz")
+sha512sums=('9ba96da560d3e0a3e38febc6f10d2b3d8019b63ffa0a4c6fa9032efd019333df0367bdd3056faba22517f59f4ef27b18d52429606ed2b8306f69778fd755beb2')
+b2sums=('a658e5fb66ebb091560d9e0b8bddd99ec7e7e84c58d9074057fd612a2eb0abf637778ea06c3481dd4d5179a917d47a08f25533d9002c1a915037a83279e2381a')
+
+build() {
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=None \
+        -DFLUID_DAEMON_ENV_FILE=/etc/conf.d/fluidsynth \
+        -DLIB_SUFFIX=32 \
+        -Denable-ladspa=ON \
+        -Denable-portaudio=ON \
+        -Wno-dev \
+        -B build \
+        -S "${_name}-${pkgver}"
+  make -C build VERBOSE=1
+}
+
+check() {
+  make -C build -k check
+}
+
+package() {
+  depends+=(libasound.so libglib-2.0.so libgmodule-2.0.so libgobject-2.0.so
+  libinstpatch-1.0.so libjack.so libportaudio.so libsndfile.so)
+
+  make -C build DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/{include,share,bin}
+}
+# vim: ts=2 sw=2 et: